Hello, I have a sprites problem.

[honkytonk]

There are: 8 "cat" sprites on top, 8 "nou" sprites on bottom
4 "bar" sprites which are bars on middle
1 "curs" sprite which is a dot.
Moving the bars with the mouse works.
The random movement of "cat" works.
The problem: When I launch the movement of the "cat" (with [go]), and I move a bar, it accelerates the movement of the "cat". And I dont understand why ??
What's going on ?
Thank you for.


    NOMAINWIN
    mapw=1000: maph= 500
   WindowWidth=mapw+15: WindowHeight=maph+40
   UpperLeftX = 10: UpperLeftY = 10
   BUTTON #w.go, "Go !", [go], UL, 20, 10, 40, 20
  GRAPHICBOX #w.g, 5, 5, mapw, maph
   OPEN "Manif" FOR window_nf AS #w
   #w, "TRAPCLOSE [closeHelp]"
   #w.g, "when leftButtonDown [scanne]"
   #w.g, "when leftButtonMove [MoveCmd]"
   #w.g, "when rightButtonDown [coord]"
   #w.g, "down;fill lightgray;color white;backcolor lightgray"
   #w.g, "getbmp fond 5 5 ";" ";mapw;" ";maph
   #w.g, "background fond"
   dim cat$(10): dim nou$(10): dim bar$(10): dim mapx(1000): dim mapy(500)
   bp$="aa.bmp bb.bmp cc.bmp dd.bmp ee.bmp ff.bmp gg.bmp hh.bmp "+_
   "ii.bmp jj.bmp kk.bmp ll.bmp mm.bmp nn.bmp oo.bmp pp.bmp "+_
   "bar1.bmp bar2.bmp bar3.bmp bar4.bmp"
   LOADBMP "curs","bmp\curso.bmp": #w.g, "addsprite curs curs"
   for x=1 to 8
     cat$(x)=word$(bp$,x): nou$(x)=word$(bp$,x+8)
     LOADBMP cat$(x),"bmp\";cat$(x)
     LOADBMP nou$(x),"bmp\";nou$(x)
     #w.g, "addsprite ";cat$(x);" ";cat$(x)
     #w.g, "addsprite ";nou$(x);" ";nou$(x)
   next x
   for x=1 to 4
     bar$(x)=word$(bp$,x+16)
     LOADBMP bar$(x),"bmp\";bar$(x)
      #w.g, "addsprite ";"lever";str$(x);" ";bar$(x)
   next x
   for x=1 to 8
      #w.g, "spritexy ";cat$(x);" ";"-200";" ";"150" 'expulse sprites
      #w.g, "spritexy ";nou$(x);" ";"-200";" ";"150"
      #w.g, "drawsprites"
   next x
   xa=100: ya=250
   for a=1 to 4
      #w.g, "spritexy ";"lever";str$(a);" ";"-200";" ";"150" 'expulse sprites
      #w.g, "spritexy ";"lever";str$(a);" ";xa;" ";ya 'place sprites bars
      xa=xa+150
      #w.g, "drawsprites": #w.g, "flush"
   next a
   x=20: y=30
   for a=1 to 8
      #w.g, "spritexy ";cat$(a);" ";x;" ";y 'place sprites cats
      x=x+90
      #w.g, "drawsprites": #w.g, "flush"
   next a
   xx=20: yy=400
   for a=1 to 8
      #w.g, "spritexy ";nou$(a);" ";xx;" ";yy 'place sprites nou
      xx=xx+90
      #w.g, "drawsprites": #w.g, "flush"
   next a
 wait
 [go]
   for a=1 to 8
   scan
     ux=int(rnd(1)*2) + 1: uy=int(rnd(1)*2) + 1
     #w.g, "spritemovexy ";cat$(a);" ";ux;" ";uy
     #w.g, "drawsprites"
     if mapx(ux)=1 or mapy(uy)=1 then
       #w.g, "spritemovexy ";cat$(a);" ";ux-(ux*2);" ";uy-(uy*2)
       #w.g, "drawsprites"
     end if
     gosub [pause]
   next a
 wait
 [scanne]
       #w.g, "spritexy curs ";MouseX;" ";MouseY   ' move sprite 'curs' under the mouse to know collides event.
       #w.g, "spritecollides curs list$"
          currentLever$ = word$(list$,1)
 [MoveCmd]
   currentY = MouseY: currentX = MouseX
   select case val(right$(currentLever$,1))
     case 1
      #w.g, "spritexy ";currentLever$;" ";currentX;" ";currentY
     for h=currentX to currentX+70
        mapx(h)=1: mapy(currentY)=1: mapy(currentY+1)=1
     next h
     case 2
      #w.g, "spritexy ";currentLever$;" ";currentX;" ";currentY
      for h=currentX to currentX+70
        mapx(h)=1: mapy(currentY)=1: mapy(currentY+1)=1
      next h
     case 3
      #w.g, "spritexy ";currentLever$;" ";currentX;" ";currentY
      for h=currentX to currentX+70
        mapx(h)=1: mapy(currentY)=1: mapy(currentY+1)=1
      next h
     case 4
      #w.g, "spritexy ";currentLever$;" ";currentX;" ";currentY
      for h=currentX to currentX+70
        mapx(h)=1: mapy(currentY)=1: mapy(currentY+1)=1
      next h
   end select
    #w.g, "drawsprites"
 wait
 [coord]
   mx=MouseX: my=MouseY
   #w.g, "color black;backcolor lightgray"
   #w.g, "place ";mx;" ";my: #w.g, "\ ";mx;"  ";my
 wait
   [pause]
       timer 300, [temps]
       wait
       [temps]
       timer 0
 return
 [closeHelp]
   for x=1 to 8
      unLOADBMP cat$(x): unLOADBMP nou$(x)
   next x
   for x=1 to 4
      unLOADBMP bar$(x)
   next x
   unLOADBMP "curs"
   CLOSE  #w
   END


[Rod]

There are a couple of issues. First is that FLUSH has no place in sprite based animation, remove it. Second is that spritemovex moves every draw sprites command. So when you start the mouse move event you get hundreds of mouse move events that lead to a spritemovex move. The solutions, use fewer draw sprite commands, use spritexy that does not move unless you specify.

Hard to give exact code because we don't have the sprite images.

[honkytonk]

The sprites are here--> libertybasic.fr/upload/the-sprites_zip.zip
I will try flush issue

[Rod]

Yeah, not an easy fix. You need a new strategy. Generally speaking in a sprite animation you update all of the spritexy then issue a single draw sprites command. You never use flush with sprites.

You can't really have two independent routines driving the timing of the animation. You can have one set of sprites reacting to the mouse and you can have another set move a step at a time automatically or randomly but you need to get a CYCLE OF ANIMATION into your mind.

The animation needs to cycle regularly, say with a timer. Within each cycle you need to manage what sprites move and how far they move and what drives the movement. So the mouse move event might change the xy of a set of sprites but it won't show till the animation cycles. So too the automated advance of the cats, they need to move a step at a time every cycle, not every mouse move. Spritemovexy would be ok if you cycle but not if you allow mouse move to draw sprites each call.

There are plenty examples and tutorials posted.

[Rod]

Here are three sets of sprites being moved by three different methods. Automated, leftButtonDown and leftButtonMove. There is one cycle and one draw sprites command. Flush is not needed because the scene is drawn repeatedly. Sprite drawing uses no memory so Flush is not needed and will crash your program being called so often.

  nomainwin
   s=7
   dim s(s,4) 'x,y,dx,dy
   x=1
   y=2
   dx=3
   dy=4
   for n= 1 to s
       s(n,x)=int(rnd(0)*790)
       s(n,y)=int(rnd(0)*590)
       s(n,dx)=8-rnd(0)*16
       s(n,dy)=8-rnd(0)*16
   next

   WindowWidth  = 800
   WindowHeight = 600
   UpperLeftX = int((DisplayWidth-WindowWidth)/2)
   UpperLeftY = int((DisplayHeight-WindowHeight)/2)
   graphicbox #1.gb 0,0, 800, 600
   open "Sprite Demo" for graphics_nsb as #1
   #1 "trapclose [quit]"
   #1.gb "down ; fill black ; backcolor blue ; place 5 14; circlefilled 4 ; backcolor white ; place 5 4 ; circlefilled 4 ; getbmp sblue 0 0 10 20"
   #1.gb "down ; fill black ; backcolor cyan ; place 5 14; circlefilled 4 ; backcolor white ; place 5 4 ; circlefilled 4 ; getbmp scyan 0 0 10 20"
   #1.gb "down ; fill black ; backcolor red ; place 5 14; circlefilled 4 ; backcolor white ; place 5 4 ; circlefilled 4 ; getbmp sred 0 0 10 20"
   #1.gb "fill black ; getbmp bac 0 0 800 600 ; background bac"
   for n= 1 to 5
       #1.gb "addsprite s";n;" sblue"
       #1.gb "spritexy s";n;" ";s(n,x);" ";s(n,y)
   next
   #1.gb "addsprite s";6;" scyan"
   #1.gb "spritexy s";6;" ";s(6,x);" ";s(6,y)
   #1.gb "addsprite s";7;" sred"
   #1.gb "spritexy s";7;" ";s(7,x);" ";s(7,y)

   #1.gb "when leftButtonDown [movecyan]"
   #1.gb "when leftButtonMove [movered]"

   timer 33,[draw]

   [draw]

   #1.gb "drawsprites"
   for n=1 to 5
       s(n,dx)=s(n,dx)
       s(n,dy)=s(n,dy)
       s(n,x)=s(n,x)+s(n,dx)
       s(n,y)=s(n,y)+s(n,dy)
       'bounce off walls
       if s(n,x)>=790 then s(n,dx)=s(n,dx)*-1
       if s(n,y)>=590 then s(n,dy)=s(n,dy)*-1
       if s(n,x)<0 then s(n,dx)=s(n,dx)*-1
       if s(n,y)<0 then s(n,dy)=s(n,dy)*-1
       #1.gb "spritexy s";n;"  ";s(n,x);" ";s(n,y)
   next
   #1.gb "spritexy s";6;"  ";s(6,x);" ";s(6,y)
   #1.gb "spritexy s";7;"  ";s(7,x);" ";s(7,y)
   wait

[movecyan]
   s(6,x)=MouseX
   s(6,y)=MouseY
   wait

[movered]
   s(7,x)=MouseX
   s(7,y)=MouseY
   wait

[quit]
   timer 0
   close #1
   end





[honkytonk]

Ah yes it is very different, and really very efficient.
I will adapt, thank you very much.