Copy Folder, sub folders, and all files

[xxgeek]

Copy Paste this into JB IDE and save it to it's own folder before running . It creates a vbs script .

Use this to copy folders from a source folder to a destination folder including sub folders and files.
Adapt it to use as a sub or function

Problem was I only tested copying a folder to a drive. 
When a drive is destination, the path returned a "\" at the end of the path
When a folder was selected, there was no "\" at the end of the path
To copy to a destination folder it needed the "\"

Sorry folks, I messed up !!!

Fixed and improved - Hopefully bullet proof. Save this file to it's own folder and I recommend using test folders first.


'Author -xxgeek - a member of the Just Basic Forums - https://justbasiccom.proboards.com/
'Purpose - Copies selected source folder to selected destination folder includes all sub folders and all files

'posted to help others learn by example and keep Just Basic relevant by showing
'what Just Basic and Windows can do working together

'Two prompts: First to select a source folder, and the second to select a destination folder

nomainwin
global selectedpath$, t
t = 0
q$ = chr$(34) 'double quotes

'get source folder
a$ = getFolder$(a$)
 sourceFolder$ = selectedpath$

'get destination folder
a$ = getFolder$(a$)
if right$(selectedpath$,1) <> "\" then selectedpath$ = selectedpath$;"\"
destFolder$ = selectedpath$

' VBScript to copy folder
'make sure no previous copyfolder.vbs exists, delete if true
copy$ = "copyfolder.vbs"
if fileExists(DefaultDir$,copy$) then kill DefaultDir$;"\";copy$
open copy$ for output as #1
#1, "Dim FSO"
#1, "Set FSO = CreateObject(";q$;"Scripting.FileSystemObject";q$;")"
#1, "FSO.CopyFolder ";q$;sourceFolder$;q$;", ";q$;destFolder$;q$
close #1

'run folder copy script
run "wscript ";copy$

'function for checking file existence
function fileExists(path$, filename$)
 dim info$(0, 0)
 files path$, filename$, info$()
 fileExists = val(info$(0, 0)) 'non zero is true
end function

'function for checking folder existence
function pathExists(path$)
 pathExists = (mkdir(path$)=183)
end function

'functions for making the folder dialog window
'Must add selectedpath$ to "global" at top of your bas file eg: global, selectedpath$
function getFolder$(a$)
q$ = chr$(34) ' quotes
'write the following vbs script to temp file named FolderDialog.vbs
 folderDialog$ = "FolderDialog.vbs"
open folderDialog$ for output as #1
'print each line to file (FolderDialog.vbs)
#1,"Function BrowseFolder( myStartLocation, blnSimpleDialog )"
#1,"Const MY_COMPUTER = &H11&"
#1,"Const WINDOW_HANDLE = 0"
#1,"Dim numOptions, objFolder, objFolderItem"
#1,"Dim objPath, objShell, strPath, strPrompt"
if t <> 0 then [destDialog]
#1,"strPrompt = ";q$;"Select Source Folder (copies folder, sub folders and all files) ";q$ 'source dialog
if t = 0 then t = t + 1 : goto [bypass]
[destDialog]
#1,"strPrompt = ";q$;"Select Destination Folder (pastes selected source folder) ";q$ 'destination dialog
[bypass]
#1,"If blnSimpleDialog = True Then"
#1,"numOptions = 0"
#1,"Else"
#1,"numOptions = &H10&"
#1,"End If"
#1,"Set objShell = CreateObject( ";q$;"Shell.Application";q$;" )"
#1,"If UCase( myStartLocation ) = ";q$;"MY COMPUTER";q$;" Then"
#1,"Set objFolder = objShell.Namespace( MY_COMPUTER )"
#1,"Set objFolderItem = objFolder.Self"
#1,"strPath = objFolderItem.Path"
#1,"Else"
#1,"strPath = myStartLocation"
#1,"End If"
#1,"Set objFolder = objShell.BrowseForFolder( WINDOW_HANDLE, strPrompt, _"
#1,"numOptions, strPath )"
#1,"If objFolder Is Nothing Then"
#1,"BrowseFolder = ";q$;q$
#1,"Exit Function"
#1,"End If"
#1,"Set objFolderItem = objFolder.Self"
#1,"objPath = objFolderItem.Path"
#1,"BrowseFolder = objPath"
#1,"End Function"
#1,"Dim bf"
#1,"bf = BrowseFolder( ";q$;"My Computer";q$;", False )"
#1,"Dim fso : Set fso = CreateObject(";q$;"Scripting.FileSystemObject";q$;")"
#1,"Dim sp : sp = fso.GetFile(Wscript.ScriptFullName)"
#1,"Dim fp: fp = fso.GetParentFolderName(sp) & ";q$;"\FolderPath.txt";q$
#1,"Dim f : Set f = fso.CreateTextFile(fp)"
#1,"f.WriteLine bf"
#1,"f.Close"
close #1

'loop until FolderDialog.vbs existence is verified
do
 res = fileExists(DefaultDir$,folderDialog$)
  if res then exit do
  scan
loop until res

'run the script (creates temp file FolderPath.txt)
 run "wscript ";"FolderDialog.vbs"

'loop until the selected folder path is written to temp file (FolderPath.txt)
do
 folderpath$ = "FolderPath.txt"
 res = fileExists(DefaultDir$,folderpath$)
  if res then exit do
  scan
loop until res

'get the text in FolderPath.txt (the selected path of folder)
 open folderpath$ for input as #1
 line input #1, line$(x)
 selectedpath$ = line$(x)
close #1

'delete both temp files (FolderPath.txt, and FileDialog.vbs)
 res = fileExists(DefaultDir$,folderpath$)
  if res then kill folderpath$
    res = fileExists(DefaultDir$,folderDialog$)
  if res then kill folderDialog$
  if selectedpath$ = "" or left$(selectedpath$,1)  = ":" then notice "No Folder selected" : end
  if p = 0  and right$(selectedpath$,1) = "\" then confirm "You have chosen Drive "+selectedpath$+" Are you sure you want to copy an entire drive?";r$ : if r$ <> "yes" then end
end function

[honky]

It would be wise to create a new folder (with same name, or "copy from..."), because otherwise the contents of the original folder are spilled in bulk in a folder (ex "my documents") which may contain others.

[xxgeek]

Jul 19, 2021 8:45:29 GMT honky said:

It would be wise to create a new folder (with same name, or "copy from..."), because otherwise the contents of the original folder are spilled in bulk in a folder (ex "my documents") which may contain others.

I messed up, problem posted above.

Thanks for pointing it out Honky, before the whole world messed up their filing systems.

Ok, maybe not the whole world. A few die hard JB fans maybe

[xxgeek]

The code above is fixed and improved to catch errors.

Now working on a mutli file select dialog for JB

[honky]

How come your VBS code is executed?
Who runs it, who compiles it?
What is this mystery ?

[tsh73]

Jul 21, 2021 15:11:40 GMT honky said:

How come your VBS code is executed?
Who runs it, who compiles it?
What is this mystery ?

this part of code
'run the script (creates temp file FolderPath.txt)
 run "wscript ";"FolderDialog.vbs"

So it is wscript who runs the code, compiling on the fly (or interpreting).
If you has permissions that is.
My job machine does not allow me run wscript.

[xxgeek]

Jul 21, 2021 15:59:46 GMT tsh73 said:

Jul 21, 2021 15:11:40 GMT honky said:

How come your VBS code is executed?
Who runs it, who compiles it?
What is this mystery ?

this part of code
'run the script (creates temp file FolderPath.txt)
 run "wscript ";"FolderDialog.vbs"

So it is wscript who runs the code, compiling on the fly (or interpreting).
If you has permissions that is.
My job machine does not allow me run wscript.

The script run "wscript ";"FolderDialog.vbs" writes a file with the selected path (does this twice, once for source, then for destination'


The following writes the script that copies the source folder to the destination folder
' VBScript to copy folder
'make sure no previous copyfolder.vbs exists, delete if true
copy$ = "copyfolder.vbs"
if fileExists(DefaultDir$,copy$) then kill DefaultDir$;"\";copy$
open copy$ for output as #1
#1, "Dim FSO"
#1, "Set FSO = CreateObject(";q$;"Scripting.FileSystemObject";q$;")"
#1, "FSO.CopyFolder ";q$;sourceFolder$;q$;", ";q$;destFolder$;q$
close #1

'run folder copy script
run "wscript ";copy$

[honky]

"wscript" is therefore present in Windows, is it a compiler (interpreter)?

[xxgeek]

Jul 22, 2021 10:25:05 GMT honky said:

"wscript" is therefore present in Windows, is it a compiler (interpreter)?

It is an interpreter, built into windows since 95.  - wscript.exe  in (c:\Windows\System32) 
en.wikipedia.org/wiki/Windows_Script_Host


cscript.exe  is the command interpreter (pops up a black command window) ugly


and VBSscript
en.wikipedia.org/wiki/VBScript


So useful and powerful it could be dangerous!
Not only could it be used to show your password(s), it could change them too.

When calling an exe like wscript or cscript you don't need to add the extension .exe

[honky]

Very interesting and informative.
Thank you so much.

[xxgeek]

Jul 23, 2021 7:59:07 GMT honky said:

Very interesting and informative.
Thank you so much.

Welcome honky. here's some more info to help you along.

When writing text files that contain quotes (like a sed file) this is how I do it.
Instead of typing out a whole wack of +chr$(34)+ in your code, use a variable and ; It makes the code easier to read while coding it as well as writing it.


[makeSed]
q$=chr$(34) ' quotes to be printed around files and paths in sed file text"
  sedfile$=fnamenobas$;".sed"
open sedfile$ for output as #sed
#sed "[Version]"
#sed "Class=IEXPRESS"
#sed "SEDVersion=3"
#sed "[Options]"
#sed "PackagePurpose=InstallApp"
#sed "ShowInstallProgramWindow=1"
#sed "HideExtractAnimation=1"
#sed "UseLongFileName=1"
#sed "InsideCompressed=0"
#sed "CAB_FixedSize=0"
#sed "CAB_ResvCodeSigning=0"
#sed "RebootMode=N"
#sed "InstallPrompt=%InstallPrompt%"
#sed "DisplayLicense=%DisplayLicense%"
#sed "FinishMessage=%FinishMessage%"
#sed "TargetName=%TargetName%"
#sed "FriendlyName=%FriendlyName%"
#sed "AppLaunched=%AppLaunched%"
#sed "PostInstallCmd=%PostInstallCmd%"
#sed "AdminQuietInstCmd=%AdminQuietInstCmd%"
#sed "UserQuietInstCmd=%UserQuietInstCmd%"
#sed "SourceFiles=SourceFiles"
#sed "[Strings]"
#sed "InstallPrompt="
#sed "DisplayLicense="
#sed "FinishMessage="
 exe$=fnamenobas$;".exe"
#sed "TargetName=";q$;DefaultDir$;"\EXE\";exe$;q$
#sed "FriendlyName=";q$;fnamenobas$;q$
#sed "AppLaunched=";q$;exe$;q$
#sed "PostInstallCmd=<None>"
#sed "AdminQuietInstCmd="
#sed "UserQuietInstCmd="
#sed "FILE0=";q$;exe$;q$
 sedtkn$=fnamenobas$;".tkn"
#sed "FILE1=";q$;sedtkn$;q$
 sll1$="vbas31w.sll"
 sll2$="vgui31w.sll"
 sll3$="voflr31w.sll"
 dll1$="vthk31w.dll"
 dll2$="vtk1631w.dll"
 dll3$="vtk3231w.dll"
 dll4$="vvm31w.dll"
 dll5$="vvmt31w.dll"
#sed "FILE2=";q$;sll1$;q$
#sed "FILE3=";q$;sll2$;q$
#sed "FILE4=";q$;sll3$;q$
#sed "FILE5=";q$;dll1$;q$
#sed "FILE6=";q$;dll2$;q$
#sed "FILE7=";q$;dll3$;q$
#sed "FILE8=";q$;dll4$;q$
#sed "FILE9=";q$;dll5$;q$
#sed "[SourceFiles]"
#sed "SourceFiles0=";q$;DestPath1$;q$
#sed "[SourceFiles0]"
#sed "%FILE0%="
#sed "%FILE1%="
#sed "%FILE2%="
#sed "%FILE3%="
#sed "%FILE4%="
#sed "%FILE5%="
#sed "%FILE6%="
#sed "%FILE7%="
#sed "%FILE8%="
#sed "%FILE9%="
 close #sed




This is what gets written to the sed file for iexpress to read, and create the exe file.


[Version]
Class=IEXPRESS
SEDVersion=3
[Options]
PackagePurpose=InstallApp
ShowInstallProgramWindow=1
HideExtractAnimation=1
UseLongFileName=1
InsideCompressed=0
CAB_FixedSize=0
CAB_ResvCodeSigning=0
RebootMode=N
InstallPrompt=%InstallPrompt%
DisplayLicense=%DisplayLicense%
FinishMessage=%FinishMessage%
TargetName=%TargetName%
FriendlyName=%FriendlyName%
AppLaunched=%AppLaunched%
PostInstallCmd=%PostInstallCmd%
AdminQuietInstCmd=%AdminQuietInstCmd%
UserQuietInstCmd=%UserQuietInstCmd%
SourceFiles=SourceFiles
[Strings]
InstallPrompt=
DisplayLicense=
FinishMessage=
TargetName="E:\BAS2EXE_Testing\EXE\BAS2EXE_v1.1FinalCopy.exe"
FriendlyName="BAS2EXE_v1.1FinalCopy"
AppLaunched="BAS2EXE_v1.1FinalCopy.exe"
PostInstallCmd=<None>
AdminQuietInstCmd=
UserQuietInstCmd=
FILE0="BAS2EXE_v1.1FinalCopy.exe"
FILE1="BAS2EXE_v1.1FinalCopy.tkn"
FILE2="vbas31w.sll"
FILE3="vgui31w.sll"
FILE4="voflr31w.sll"
FILE5="vthk31w.dll"
FILE6="vtk1631w.dll"
FILE7="vtk3231w.dll"
FILE8="vvm31w.dll"
FILE9="vvmt31w.dll"
[SourceFiles]
SourceFiles0="E:\BAS2EXE_Testing\Projects\BAS2EXE_v1.1FinalCopy"
[SourceFiles0]
%FILE0%=
%FILE1%=
%FILE2%=
%FILE3%=
%FILE4%=
%FILE5%=
%FILE6%=
%FILE7%=
%FILE8%=
%FILE9%=

Information is something all humans should share, to make a better world.........a lot faster.
Too bad too many don't get that now or in the past or we'd have industries on Mars by now.

[honky]

A little too esoteric for me.
But hey, that gives something to study.
It's good, thank you

[xxgeek]

'VBScript to copy folder
q$ = chr$(34)
'make sure no previous copyfolder.vbs exists, delete if true
copy$ = "copyfolder.vbs"
if fileExists(DefaultDir$,copy$) then kill DefaultDir$;"\";copy$
open copy$ for output as #1
#1, "Dim FSO"
#1, "Set FSO = CreateObject(";q$;"Scripting.FileSystemObject";q$;")"
#1, "FSO.CopyFolder ";q$;sourceFolder$;q$;", ";q$;destFolder$;q$
close #1

'confirm "Large amounts of data take more time to complete. There will be NO progress bar, and no notification of completion. You can use taskmanager to watch progress if desired and at bottom left - More Details - then - Performance Tab - ."+chr$(13)+chr$(13)+" Would you like to open taskmanager?";taskman$
'if taskman$ = "yes" then run "start cmd.exe /c";q$;" Taskmgr";q$
'cmd.exe /c";q$;"

'run folder copy script
run "wscript ";copy$


The above code is taken from my FolderCopy.bas post. It is a small piece of the bigger picture.
It is small and easier to learn from since the lines we want to dicsuss are 3 in total.
lines starting with #1,
I could have use print #1, blah blah, but it's not necessary to put print in front of a command
(lazy issues here)

Those lines are what the windows scripting host will read, and execute.
#1, "Dim FSO"
#1, "Set FSO = CreateObject(";q$;"Scripting.FileSystemObject";q$;")"
#1, "FSO.CopyFolder ";q$;sourceFolder$;q$;", ";q$;destFolder$;q$

The way they sit here in JB code, the windows scripting host would give an error on line 1, character 1, because
as they are the scripting host doesn't know what to do with them.

The scripting host wants to see them like this, as they were originally written.

Dim FSO
Set FSO = CreateObject("Scripting.FileSystemObject")
FSO.CopyFolder "sourceFolder", "destFolder"
We need jb to write the file for us, and then execute it for us.
In order to do that we need to use jbcode to open a file, print those lines, then RUN the vbs file created.

If you were to provide actual paths to folders, and copied the text to a new file named anything.vbs (using notepad) and then
were to click that file, the code would execute, and copy one folder(sourcefolder) to the folder(destfolder)
Something like this:

Dim FSO
Set FSO = CreateObject("Scripting.FileSystemObject")
FSO.CopyFolder "d:\testing\jbfiles", "e:\finished code\jbcode"

Of course you would provide paths to actual folders on YOUR system

Substitute any path you wish for source, and dest folders.
As is the above will copy all files in source to dest, but NO folders, sub folders or their files.
To copy all the subfolders we need to put an \ at the end of the destFolder path. (done later in the code, not shown here)
if left$(destFolder,1) <> "\" then destFolder$ = destFolder$;"\"
In my program I use variables for the paths like DefaultDir$, and DestPath$ which are just strings containing paths to folders


Now, on to what's important...
We can't write the lines to the copy.vbs file in jb the way it is, because in jb code the " is used to wrap strings
and will get confused if we try to write a line like "Hi there, how are you", "I saw you at the mall today"
That line has quotes inside quotes, and jb debugger will tell you "syntax error", and stop debugging so you can fix it.
We could write it like this:
chr$(34) + "Hi there, how are you" + chr$(34) + chr$(34) + ", " + chr$(34) + chr$(34) + "I saw you at the mall today" + chr$(34)

Personally I find that too much work, so instead I set chr$(34) as a variable named q$ - learned that from tsh73's code
(he actually likes qq$, but I'm too lazy even for that. I write a ton of code, and it gets very tedious.

So, the code becomes q$;"Hi there, how are you";q$;", ";q$;"I saw you at the mall today";q$ (a lot less typing)
Notice the first comma doesn't need q$ before or after, because it is within the original quotes. But the second comma IS within quotes originally, so it needs to be wrapped in q$, or chr$(34)
Also the ; (semi colon) needs to be on any side of the q$ that has " (quote)
and don't forget about the space after the second comma

Use whatever method you find works best for you, there is no (this is the only way, or this is the right way)
If it's easier to use the word quote$ = chr$(34) instead of q$ then that's YOUR right way.

Try a few tests with small lines and experiment with other characters as well,
like chr$(13) is the carriage return in ASCII code and chr$(39) is the single quote '

Hope this helps anyone having difficulty with this type of issue.

When you get better at it try to write the jb code to copy this script to a file.
This is the script that creates the folder dialog window for choosing a folder.
Not as hard as you think it is, just tedious.

If you were to copy the following text "as is" into notepad and save as a .vbs file, you click that file and the
folder dialog will come up to choose a folder. Nothing will happen though, because it needs further
coding to do something with the chosen folder. It will create a file named FolderPath.txt that has the path (string) of the folder you select.
the file will be in the same folder as you execute this code, so put it in it's own folder before clicking it.


Function BrowseFolder( myStartLocation, blnSimpleDialog )
Const MY_COMPUTER = &H11&
Const WINDOW_HANDLE = 0
Dim numOptions, objFolder, objFolderItem
Dim objPath, objShell, strPath, strPrompt
strPrompt = "Select a folder"
numOptions = 0
Else
numOptions = &H10&
End If
Set objShell = CreateObject( "Shell.Application" )
If UCase( myStartLocation ) = "MY COMPUTER" Then
Set objFolder = objShell.Namespace( MY_COMPUTER )
Set objFolderItem = objFolder.Self
strPath = objFolderItem.Path
Else
strPath = myStartLocation
End If
Set objFolder = objShell.BrowseForFolder( WINDOW_HANDLE, strPrompt, _
numOptions, strPath )
If objFolder Is Nothing Then
BrowseFolder = ""
Exit Function
End If
Set objFolderItem = objFolder.Self
objPath = objFolderItem.Path
BrowseFolder = objPath
End Function
Dim bf
bf = BrowseFolder( "My Computer", False )
Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
Dim sp : sp = fso.GetFile(Wscript.ScriptFullName)
Dim fp: fp = fso.GetParentFolderName(sp) & "\FolderPath.txt"
Dim f : Set f = fso.CreateTextFile(fp)
f.WriteLine bf
f.Close