Bump mapping

[Rod]

bump5.bmp (101.05 KB)

My latest project. Looking for lots of advice. Bump mapping, taking an image and using it as the contour map of computer drawn terrain. In this case undersea landscape. It will be a Submarine adventure eventually.

So the bump mapping is progressing but the drawing of the landscape not so much. I need hidden line removal I think. Possible some height managment. Perhaps even a little perspective and some reduction in height of far away objects.

The code so far: Use the cursor keys to move the "view". You need to click in the undersea window first. It only moves a click at a time for now.



nomainwin
   WindowWidth  = 800
   WindowHeight = 320
   UpperLeftX   = (DisplayWidth-WindowWidth)/2
   UpperLeftY   = (DisplayHeight-WindowHeight)/2
   graphicbox #1.gb, 0,0,800,320
   open "3D Height Mapping" for graphics_nf_nsb as #1
   #1 "trapclose [quit]"
   #1.gb "down"
   for n=0 to 320
   #1.gb "color 0 0 ";(256/320)*(320-n)
   #1.gb "line 0 ";n;" 800 ";n
   #1.gb "size 4"
   next
   #1.gb "flush sea"
   WindowWidth=320
   WindowHeight=320
   open "bump" for graphics_nf_nsb as #2
   loadbmp "bump","bump5.bmp"
   #2 "down ; drawbmp bump 0 0 ;flush bak"


   eyeX=150
   eyeZ=150
   eyeA=90
   fov=30
   dim hmap(320,320)
   dim maxh(320)

   open "bump5.bmp" for binary as #bmp
   x=1
   y=1
   seek #bmp,1078
   for y=320 to 1 step -1
       for x= 1 to 320
           n$ = INPUT$(#bmp, 1)
           hmap(x,y)=asc(n$)
       next
   next
   close #bmp

   #1.gb "when characterInput [keyboardinterrupt]"
   #1.gb "setfocus"

   [drawit]
   'print eyeX,eyeZ,eyeA

   z=160

   #1.gb "discard ; redraw sea"
   while z>=20

       eyeL=eyeA-fov
       eyeR=eyeA+fov
       eyeX1=eyeX+(z*sin(eyeL/57.29577951))
       eyeZ1=eyeZ+(z*cos(eyeL/57.29577951))
       eyeX2=eyeX+(z*sin(eyeR/57.29577951))
       eyeZ2=eyeZ+(z*cos(eyeR/57.29577951))
       stepX=(eyeX2-eyeX1)/z
       stepZ=(eyeZ2-eyeZ1)/z
       'if eyeX2<eyeX1 then stepX=-160/z else stepX=160/z
       'if eyeZ2<eyeZ1 then stepZ=-160/z else stepZ=160/z

       sX=eyeX2
       sZ=eyeZ2
       if z=160 then
           #2 "discard ; redraw bak ; color red"
           #2 "line ";eyeX;" ";eyeZ;" ";eyeX1;" ";eyeZ1
           #2 "line ";eyeX;" ";eyeZ;" ";eyeX2;" ";eyeZ2
       end if


       scrx=0
       for x=0 to z
           m=800/z
           vX=sX
           vZ=sZ
           if sX<0 then vX=sX+320
           if sX>320 then vX=sX-320
           if sZ<0 then vZ=sZ+320
           if sZ>320 then vZ=sZ-320
           y=320-hmap(int(vX),int(vZ))
           #2 "set ";vX;" ";vZ
           #1.gb "color 0 0 ";160-z+y
           '#1.gb "backcolor ";0;" ";0;" ";z+50
           #1.gb "line ";scrx;" ";y;" ";scrx+m;" ";y
           '#1.gb "place ";scrx;" 320 ; boxfilled  ";scrx+m;" ";y
           scrx=scrx+m
           sX=sX-stepX
           sZ=sZ-stepZ
       next
       z=z-20
   wend
   wait


   [keyboardinterrupt]
   'this loop gets called every time a key is pressed
   k=asc(right$(Inkey$,1))
   if k=39 then eyeA=eyeA-5
   if eyeA<0 then eyeA=eyeA+360
   if k=38 then
       eyeX=eyeX+(1*sin(eyeA/57.29577951))
       eyeZ=eyeZ+(1*cos(eyeA/57.29577951))
   end if
   if k=37 then eyeA=eyeA+5
   if eyeA>360 then eyeA=eyeA-360
   if k=40 then
       eyeX=eyeX-(1*sin(eyeA/57.29577951))
       eyeZ=eyeZ-(1*cos(eyeA/57.29577951))
   end if
   if eyeX>320 then eyeX=eyeX-320
   if eyeZ<0 then eyeZ=eyeZ+320
   if eyeX<0 then eyeX=eyeX+320
   if eyeZ>320 then eyeZ=eyeZ-320
   goto [drawit]




   [quit]
   close #1
   close #2
   end





Please feel free to mash it up and fix it.

[Rod]

Getting better at drawing the landscape.






   nomainwin


   open "3D Height Mapping" for graphics_fs as #1
   #1 "trapclose [quit]"
   #1 "down"
   WindowWidth=320
   WindowHeight=320
   open "bump" for graphics_nf_nsb as #2
   loadbmp "bump","bump6.bmp"
   #2 "down ; drawbmp bump 0 0 ;flush bak"
   w=int(DisplayWidth/800)
   h=int(DisplayHeight/320)

   eyeX=150
   eyeZ=150
   eyeA=90
   fov=30
   eyeL=eyeA-fov
   eyeR=eyeA+fov
   dim hmap(320,320)


   open "bump6.bmp" for binary as #bmp
   x=1
   y=1
   seek #bmp,1078
   for y=320 to 1 step -1
       for x= 1 to 320
           n$ = INPUT$(#bmp, 1)
           hmap(x,y)=asc(n$)
       next
   next
   close #bmp

   #1 "when characterInput [keyboardinterrupt]"
   #1 "setfocus"

   [drawit]
   #2 "discard ; redraw bak ; color red"
   '#1.gb "discard ; redraw sea"

   for scrx=0 to 800 step 10
       a=eyeL+60/800*scrx
       ly=0
       for z=0 to 100 step 5

           'calculate viewing vector
           sX=eyeX+(z*sin(a/57.29577951))
           sZ=eyeZ+(z*cos(a/57.29577951))
           'step through the viewing line rolling round the bmp if required
           vX=sX
           vZ=sZ
           if sX<0 then vX=sX+320
           if sX>320 then vX=sX-320
           if sZ<0 then vZ=sZ+320
           if sZ>320 then vZ=sZ-320

           'get the height for that point on the bmp
           y = hmap(int(vX),int(vZ))
           #2 "set ";vX;" ";vZ
           if y >=ly then
               #1 "color 0 0 ";255-z*2;" ; backcolor 0 0 ";255-z*2
               #1 "place ";scrx*w;" ";DisplayHeight-ly*h;" ; boxfilled ";(scrx+10)*w;" ";DisplayHeight-y*h
               ly=y
           end if
       next
       #1 "discard ; color 0 0 20 ; backcolor 0 0 20"
       #1 "place ";scrx*w;" ";DisplayHeight-ly*h;" ; boxfilled ";(scrx+10)*w;" ";0
   next



   wait


   [keyboardinterrupt]
   'this loop gets called every time a key is pressed
   k=asc(right$(Inkey$,1))
   if k=39 then eyeA=eyeA-5
   if eyeA<0 then eyeA=eyeA+360
   if k=38 then
       eyeX=eyeX+(5*sin(eyeA/57.29577951))
       eyeZ=eyeZ+(5*cos(eyeA/57.29577951))
   end if
   if k=37 then eyeA=eyeA+5
   if eyeA>360 then eyeA=eyeA-360
   if k=40 then
       eyeX=eyeX-(5*sin(eyeA/57.29577951))
       eyeZ=eyeZ-(5*cos(eyeA/57.29577951))
   end if
   if eyeX>320 then eyeX=eyeX-320
   if eyeZ<0 then eyeZ=eyeZ+320
   if eyeX<0 then eyeX=eyeX+320
   if eyeZ>320 then eyeZ=eyeZ-320
   eyeL=eyeA-fov
   eyeR=eyeA+fov
   goto [drawit]




   [quit]
   close #1
   close #2
   end





[andya]

Hi Rod,

The new rendering process looks a lot better. Very nicely done.

I only see one place where you can tweak the code for a little more speed.

In the [DrawIt] nested loops you can do the following to eliminate 1,620 Sine/Cosine calculations per change of FOV.
   for scrx=0 to 800 step 10
       a=eyeL+60/800*scrx
       '==================================================
       'Calculate Sine and Cosine of angle only once here
       ' in the outer loop (162 sin/cos calcs total)
       aRad = a * 0.01745329251994329576923690768489
       sinA = Sin(aRad)
       cosA = Cos(aRad)
       '==================================================
       ly=0
       for z=0 to 100 step 5

           'calculate viewing vector
           '=================================================
           'Multiply pre-computed Sine and Cosine here
           ' in the inner loop
           '(used to be 1,782 sin/cos calcs total)
           sX=eyeX+(z*sinA)
           sZ=eyeZ+(z*cosA)
           '=================================================


That's all I can see to tweak right now.

[Rod]

Cool, thanks for looking, I will take that on board. Was also hoping to draw the extremities and just shift the middle but perhaps pie in the sky.

[andya]

I don't see why it's not possible.

You'll need to change the size of the Graphic Box to be the exact same size as the image you render from the height map.

For panning left or right just do a 'GetBMP' of the rendered scene, then 'DrawBMP' with positive or negative coordinates (even if image overlaps left or right, it will be clipped since the Graphic Box is the same size as the rendered height map). At that point you can calculate the updated slice of the FOV and draw just that new slice on the left or right accordingly.

Nearly the same thing with up or down panning, just move coordinates of GetBMP'd image accordingly and calc a horizontal FOV slice. Even if you don't do that for up/down panning (just do a complete FOV render for up/down changes), you will still have the speed up for left/right panning.

All in all it seems to be a very do-able concept.

[Enzo]

Locationary sprites! Impressive for such short code, wonder if I could add 'diving' to my rpg, I could have fun making underwater sprites at that perspective view angle.

[Brandon Parker]

Rod,
It looks like you might be rendering the image reversed on the horizontal plane.  It seems to me that when I am panning right, the terrain is coming into view from the left.  The same would apply for left/right ...

{:0)

Brandon Parker

[Rod]

Yes, that and a few other things are wrong with it. Stepping through is another part of the problem, detail is missed and the landscape changes height unexpectedly. Also objects placed on the map appear and disappear as I move position. Currently thinking through how to draw only the extremities. Might be a long think.

The challenge really is to turn it into a practical display engine for a game background. Its not useable as it is.

[Enzo]

Map your sea floor xy at bottom of screen and manually show sprites as a grid(x,y) array inside a seafloor()

[Rod]

I have been playing with this again. I have inserted Andya's tip and Brandon's left right correction. You will need the bmp in the earlier post or the one in this post. Save it as bump.bmp to the folder you run the .bas from. Its set to just run forwards. Rem out the block indicated to get back to keyboard movement.

I have amended the height calculation to make it look like where you are now is base height. Not strictly 3d but nice effect. I would be interested to know if it moves fast enough to bother writing more game code. Is it slow as treacle or does it run smoothly enough for an slow submarine game?





   nomainwin

   'open full screen graphics
   open "3D Height Mapping" for graphics_fs as #1
   #1 "trapclose [quit]"
   #1 "down"

   'divide the screen into 800x320 blocks
   w=(DisplayWidth/800)
   h=(DisplayHeight/320)

   'set our initial camera position
   eyeX=150
   eyeZ=150
   eyeA=90
   fov=30
   eyeL=eyeA-fov
   eyeR=eyeA+fov

   'get our height map
   dim hmap(320,320)
   open "bump.bmp" for binary as #bmp
   x=1
   y=1
   seek #bmp,1078
   for y=320 to 1 step -1
       for x= 1 to 320
           n$ = INPUT$(#bmp, 1)
           hmap(x,y)=asc(n$)
       next
   next
   close #bmp

   'set up our events
   #1 "when characterInput [keyboardinterrupt]"
   #1 "setfocus"

   [drawit]
   'for every angle/block in the X field of view
   for scrx=0 to 800 step 10
       a=eyeL+60/800*scrx
       'Calculate Sine and Cosine of angle only once thanks for the tip Andya
       aRad = a * 0.01745329251994329576923690768489
       sinA = Sin(aRad)
       cosA = Cos(aRad)
       ly=0

       'cast a ray in the z distance
       for z=0 to 100 step 5

           'calculate viewing vector using Andya's sin/cos
           sX=eyeX+(z*sinA)
           sZ=eyeZ+(z*cosA)

           'step through the viewing line rolling round the bmp if required
           vX=sX
           vZ=sZ
           if sX<0 then vX=sX+320
           if sX>320 then vX=sX-320
           if sZ<0 then vZ=sZ+320
           if sZ>320 then vZ=sZ-320

           'get the height for that point on the bmp
           y = hmap(int(vX),int(vZ))
           'reduce the height by distance close = low so starting point is always low ie we are at that height
           y = y - (100-z)
           'only draw new higher blocks
           if y >=ly then
               #1 "color 0 0 ";255-z*2;" ; backcolor 0 0 ";255-z*2
               #1 "place ";scrx*w;" ";DisplayHeight-ly*h;" ; boxfilled ";(scrx+10)*w;" ";DisplayHeight-y*h
               ly=y
           end if
       next
       'fill in the remainder
       #1 "discard ; color 0 0 20 ; backcolor 0 0 20"
       #1 "place ";scrx*w;" ";DisplayHeight-ly*h;" ; boxfilled ";(scrx+10)*w;" ";0
   next

   'rem out this block to restore keyboard input
   eyeX=eyeX+(5*sin(eyeA/57.29577951))
   eyeZ=eyeZ+(5*cos(eyeA/57.29577951))
   if eyeX>320 then eyeX=eyeX-320
   if eyeZ<0 then eyeZ=eyeZ+320
   if eyeX<0 then eyeX=eyeX+320
   if eyeZ>320 then eyeZ=eyeZ-320
   scan
   goto [drawit]
   '********************************************


   #1 "when characterInput [keyboardinterrupt]"
   #1 "setfocus"



   wait


   [keyboardinterrupt]
   'this loop gets called every time a key is pressed
   #1 "when characterInput "
   k=asc(right$(Inkey$,1))
   if k=37 then eyeA=eyeA-1                    'left
   if eyeA<0 then eyeA=eyeA+360
   if k=38 then                                'up
       eyeX=eyeX+(5*sin(eyeA/57.29577951))
       eyeZ=eyeZ+(5*cos(eyeA/57.29577951))
   end if
   if k=39 then eyeA=eyeA+1                    'right
   if eyeA>360 then eyeA=eyeA-360
   if k=40 then                                'down
       eyeX=eyeX-(5*sin(eyeA/57.29577951))
       eyeZ=eyeZ-(5*cos(eyeA/57.29577951))
   end if
   'roll round 320x320 map
   if eyeX>320 then eyeX=eyeX-320
   if eyeZ<0 then eyeZ=eyeZ+320
   if eyeX<0 then eyeX=eyeX+320
   if eyeZ>320 then eyeZ=eyeZ-320
   eyeL=eyeA-fov
   eyeR=eyeA+fov
   goto [drawit]




   [quit]
   close #1
   end




[Brandon Parker]

Rod,
It looks like these two lines became misplaced in the update...
   #1 "when characterInput [keyboardinterrupt]"
   #1 "setfocus"

I moved both to the end of the [keyboardinterrupt] branch just before the "GoTo [drawit]" line and everything worked as expected for me while driving manually with the arrow keys. Otherwise, you get one keystroke and that is it because the "when characterInput" is never triggered.


{:0)

Brandon Parker

[Rod]

Yeah, actually the original code is correct because I changed it to single step on keypress. What was happening was a whole bunch of keypresses were stacking up and it would take a good few seconds to catch up. So it kept going even though you had taken your finger of the key. Single step means it never gets ahead of itself and stops as soon as you take your finger off. Down side is it only runs at keyboard repeat speed.

If I was carrying on I would probably do some sort of "set in motion" driving where it has momentum and needs reverse to slow down. But I need Submarine graphics first.

[Brandon Parker]

I see... You meant to comment out the entire block down to the asterisks for manual operation. I completely missed that that was your way of showing the "block" of code...


{:0)

Brandon Parker