Connect4

[Rod]

I knew I had coded a Connect4, took a while to find. Being discussed elsewhere so thought this might pass on a few ideas. The AI can undoubtedly be improved.


nomainwin
   ' find how much whitespace the windows scheme is taking
   ' Anatoly's tip
   WindowWidth = 200
   WindowHeight = 200
   open "Ajusting..." for graphics_nf_nsb as #1
   #1, "home ; down ; posxy w h"
   w=200-2*w : h = 200-2*h
   close #1


   ' setup a  520 x 480 graphics view
   ' the graphic box borders are just outside the window edge
   ' the playing area is 8x7 60x60 pixels ie 480x420
   WindowWidth  = 520+w
   WindowHeight = 480+h
   UpperLeftX   = (DisplayWidth-WindowWidth)/2
   UpperLeftY   = (DisplayHeight-WindowHeight)/2
   graphicbox #1.g, 20,20,482,422
   open "Connect4" for window_nf as #1
   print #1, "trapclose [quit]"
   #1.g "down ; font consolas 16 bold"
   #1.g "backcolor darkblue ; color white"
   'visible drawing coordinates are 0 to 419 ie 420 pixels
   'draw our game graphics
   r=255
   g=128
   b=0
   For x = 60 to 0 Step -1
       #1.g "color ";r;" ";g;" ";x
       #1.g "place 0 0 ; box ";x;" ";x
       r = r-1
       g = g-1
   Next
   #1.g "place 29 29 ; backcolor white ; circlefilled 24"
   #1.g "getbmp whit 0 0 60 60"
   r=0
   g=128
   b=255
   #1.g "size 2"
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       b=b-1
   next
   #1.g "getbmp blue 0 0 60 60"
   r=128
   g=255
   b=50
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       r=r-1
   next
   #1.g "getbmp yell 0 0 60 60"

   'draw the board
   for x= 0 to 420 step 60
   for y= 0 to 360 step 60
   #1.g "drawbmp whit ";x;" ";y
   next
   next
   dim c(7,6)  '0-7 0-6 8x7 1= human 2= computer 0= free
   dim risk(56,4) 'cell risk/value c,r,risk,value
   dim d(8,2)  'delta x,y in 8 directions
   d(1,1)=1
   d(1,2)=0
   d(2,1)=1
   d(2,2)=1
   d(3,1)=0
   d(3,2)=1
   d(4,1)=-1
   d(4,2)=1
   d(5,1)=-1
   d(5,2)=0
   d(6,1)=-1
   d(6,2)=-1
   d(7,1)=0
   d(7,2)=-1
   d(8,1)=1
   d(8,2)=-1

   [human]
   #1.g "when leftButtonDown [leftclick]"
   wait

   'check the column
   [leftclick]
   c=int(MouseX/60)
   if c(c,0)>0 then wait
   'find how far we are falling
   r=0
   while c(c,r)=0 and r<6
       #1.g "drawbmp whit ";c*60;" ";(r-1)*60
       #1.g "drawbmp blue ";c*60;" ";r*60
       timer 56,[go]
       wait
       [go]
       timer 0
       r=r+1
   wend
   if c(c,r)>0 then r=r-1
   #1.g "drawbmp whit ";c*60;" ";(r-1)*60
   #1.g "drawbmp blue ";c*60;" ";r*60
   c(c,r)=1

   [computer]
   redim risk(1000,4)
   plays=0
   #1.g "when leftButtonDown"
   'check for win, required blocking move, or offensive play
   'check each cell and cast a ray in eight directions
   for c= 0 to 7
       for r= 0 to 6
           'is there a token?
           if c(c,r)>0 then
               'record token color and starting position
               token=c(c,r)
               dim l(8,4)
               for n= 1 to 8
                   l(n,1)=c  'col
                   l(n,2)=r  'row
                   l(n,3)=0  'risk
                   l(n,4)=0  'reward
               next
               'cast the ray three steps
               for ray= 1 to 3
                   'in all eight directions
                   for n=1 to 8
                       l(n,1)=l(n,1)+d(n,1)
                       l(n,2)=l(n,2)+d(n,2)
                       'if we come across a similar token count it
                       'if we count four (0-3) we have a winner / loser
                       'if we come across an empty space check if it is playable
                       'if it is playable record its risk/worth
                       'is it on the board?
                       if l(n,1)>=0 and l(n,1)<=7 and l(n,2)>=0 and l(n,2)<=6 then
                           select case
                               case c(l(n,1),l(n,2))=1 and token = 1 'risk
                                   l(n,3)=l(n,3)+1
                                   if l(n,3)=3 then notice "Human Wins" : goto [quit]
                               case c(l(n,1),l(n,2))=2 and token = 2 'reward
                                   l(n,4)=l(n,4)+1
                                   if l(n,4)=3 then notice "Computer Wins" : goto [quit]
                               case c(l(n,1),l(n,2))=0               'playable?
                                   'are we at the foot of the board or is the slot below taken
                                   if l(n,2)=6 then rowbelow=6 else rowbelow=l(n,2)+1
                                   'is the slot filled or are we at the foot of the board?
                                   if c(l(n,1),rowbelow)>0 or l(n,2)=6 then
                                       'record the risk/worth
                                       risk(plays,1)=l(n,1)
                                       risk(plays,2)=l(n,2)
                                       if token=1 then risk(plays,3)=l(n,3)
                                       if token=2 then risk(plays,4)=l(n,4)
                                       plays=plays+1
                                   end if
                           end select
                       end if
                   next
               next
               'sort moves on basis of risk/block move required
               sort risk(,56,0,3
               pc=risk(1,1)
               rr=risk(1,3)
               'sort moves on basis of reward/win move
               sort risk(,56,0,4
               'if the reward move is of higher worth take it else take the blocking move
               if risk(1,4)>rr then pc=risk(1,1)
               'here we need to think about playing the centre of the board, still to do
           end if
       next
   next

   c=pc
   'find how far we are falling
   r=0
   while c(c,r)=0 and r<6
       #1.g "drawbmp whit ";c*60;" ";(r-1)*60
       #1.g "drawbmp yell ";c*60;" ";r*60
       r=r+1
       timer 56,[g]
       wait
       [g]
       timer 0
   wend
   if c(c,r)>0 then r=r-1
   #1.g "drawbmp whit ";c*60;" ";(r-1)*60
   #1.g "drawbmp yell ";c*60;" ";r*60
   c(c,r)=2

   goto [human]


   [quit]
   close #1
   end




[code]

Looks verry nice... I won a couple of times

[tsh73]

I got bothered that AI does not close obvious threats (3 in a row, 4th coming)
And I wanted it to be more traditional 7x6

alas I did not quite understand how this AI works
so I just left
* if you can win, do it
* if you should block (3 in a row, 4th coming), do it
* else select possible column at random.
(mainwin is left open so you can see that)

Not there AI'sh I would say.
but it still wins over me every now and then ;)

to do - add some evaluation instead of random move?
At least so it should not allow player build " xx " on first two moves :)
'1. Allow for standard 7x6 field
'2. try to fix AI so it block dangerous points
'3. dismantled AI instead
numCols=8:numRows=7
numCols=7:numRows=6
'numCols=5:numRows=4    'for debug
cs=60 'cellSize
offset=20
human=1
computer=2
'word$("blue yell",player)

' nomainwin
   ' find how much whitespace the windows scheme is taking
   ' Anatoly's tip
   WindowWidth = 200
   WindowHeight = 200
   open "Ajusting..." for graphics_nf_nsb as #1
   #1, "home ; down ; posxy w h"
   w=200-2*w : h = 200-2*h
   close #1


   ' setup a  520 x 480 graphics view
   ' the graphic box borders are just outside the window edge
   ' the playing area is 8x7 60x60 pixels ie 480x420
   g.w=cs*numCols
   g.h=cs*numRows
   WindowWidth  = g.w+w+2*offset
   WindowHeight = g.h+h+2*offset
   UpperLeftX   = (DisplayWidth-WindowWidth)/2
   UpperLeftY   = (DisplayHeight-WindowHeight)/2
   graphicbox #1.g, offset,offset,g.w+2,g.h+2
   open "Connect4" for window_nf as #1
   print #1, "trapclose [quit]"
   #1.g "down ; font consolas 16 bold"
   #1.g "backcolor darkblue ; color white"
   'visible drawing coordinates are 0 to 419 ie 420 pixels
   'draw our game graphics
   r=255
   g=128
   b=0
   For x = cs to 0 Step -1
       #1.g "color ";r;" ";g;" ";x
       #1.g "place 0 0 ; box ";x;" ";x
       r = r-1
       g = g-1
   Next
   #1.g "place 29 29 ; backcolor white ; circlefilled 24"
   #1.g "getbmp whit 0 0 60 60"
   r=0
   g=128
   b=255
   #1.g "size 2"
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       b=b-1
   next
   #1.g "getbmp blue 0 0 60 60"
   r=128
   g=255
   b=50
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       r=r-1
   next
   #1.g "getbmp yell 0 0 60 60"

   'draw the board
   for i= 0 to numCols
       for j= 0 to numRows
           x=cs*i
           y=cs*j
           #1.g "drawbmp whit ";x;" ";y
       next
   next
   dim c(numCols,numRows)  '0-7 0-6 8x7 1= human 2= computer 0= free
   dim risk(numCols*numRows,4) 'cell risk/value c,r,risk,value
   dim d(8,2)  'delta x,y in 8 directions
   pi=acs(-1)
   for i = 1 to 8
       a=(i-1)*pi*2/8
       d(i,1)=int(1.5*cos(a))
       d(i,2)=int(1.5*sin(a))
   next


   [human]
   'are there moves left?
   nPossible=0
   for c = 0 to numCols-1
       if c(c,0)=0 then nPossible=nPossible+1
   next
   if nPossible=0 then
           notice "Draw (no moves)" : goto [quit]
   end if

   #1.g "when leftButtonDown [leftclick]"
   wait

   'check the column
   [leftclick]
   c=int(MouseX/cs)
   if c(c,0)>0 then wait

   player=human
   gosub [drop]
   gosub [chkWin]
   if result$<>"" then
       'draw computer token at (r,c)
       #1.g "drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
       c(c,r)=player
       'say human won
       notice "Human Wins" : goto [quit]
   end if

   [computer]
   redim risk(1000,4)
   plays=0
   #1.g "when leftButtonDown"
   'check for win, required blocking move, or offensive play
   'check each cell and cast a ray in eight directions
   '(3)nope, only check each column and get next cell in that row
   nPossible=0
   for c= 0 to numCols-1
       '--for r= 0 to numRows-1
       'get r as playable cell (c,r)
       r=0
       while c(c,r)=0 and r<numRows-1
           r=r+1
       wend
       if c(c,r)>0 then r=r-1
       if r<0 then [nextC]    'filled column
       print c;" ";r,
       'check for win
       player=computer
       gosub [chkWin]
       if result$<>"" then
           'draw computer token at (r,c)
           #1.g "drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
           c(c,r)=player
           'say computer won
           notice "Computer Wins" : goto [quit]
       end if
       'check for possible loose
       player=human
       gosub [chkWin]
       if result$<>"" then
           'computer should move at (r,c)
           '#1.g "drawbmp ";word$("blue yell",computer);" ";c*cs;" ";r*cs
           'c(c,r)=computer
           exit for
       end if
       'else we just have playable cell. How to choose?
       'let for now do random select
       print "col ";c;" is possible"
       cc(nPossible)=c
       nPossible=nPossible+1
       'next
[nextC]
   next

   if result$<>"" then    'should block
       print "should block at ";c
       pc=c
   else
       if nPossible=0 then
           notice "Draw (no moves)" : goto [quit]
       end if
       'select next if nothing urgent
       n=int(rnd(0)*nPossible)
       pc=cc(n)
       print "col ";pc;" is selected"
   end if
   print

   c=pc
   'find how far we are falling
   player=computer
   gosub [drop]

   goto [human]


   [quit]
   close #1
   end

[drop]    'by player
   'find how far we are falling
   r=0
   while c(c,r)=0 and r<numRows-1
       #1.g "drawbmp whit ";c*cs;" ";(r-1)*cs
       #1.g "drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
       r=r+1
       timer 56,[g]
       wait
       [g]
       timer 0
   wend
   if c(c,r)>0 then r=r-1
   #1.g "drawbmp whit ";c*cs;" ";(r-1)*cs
   #1.g "drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
   c(c,r)=player

return

[chkWin]    'by player
   'will player win by putting token at (r,c)?
   result$=""
   for n= 1 to 8    'directions
       maxRun=0
       curRun=0
       for i= -3 to 3
           nc=c+i*d(n,1)    'next col, row
           nr=r+i*d(n,2)
           'if on field
           if not(nc>=0 and nc<numCols and nr>=0 and nr<numRows) then [ckipCell]
           'print i, nc,nr, c(nc,nr),c(nc,nr)=player, c(nc,nr)=player or (nc=c and nr=r)
           if c(nc,nr)=player or (nc=c and nr=r) then curRun=curRun+1 else curRun=0
           if curRun>3 then 'win
               result$="win"
               exit for
           end if
[ckipCell]
       next
       'print n, i, curRun
       if result$<>"" then exit for
   next
return



[B+]

Here's mine from nearly 2 years ago, if anyone beats it let me know, it's still possible if I recall.

Rats, has some bugs.

Attachments:

Connect4 8x8 exe.zip (566.57 KB)

[tsh73]

if anyone beats it let me know, it's still possible if I recall.

I dunno about 8x8 but standard 7x6 is surely winnable by first player, if I remember what Wikipedia says.
I managed to win your program. Once. In about 20 tries ;)

What language you wrote it? C?

[B+]

Dec 6, 2020 11:25:19 GMT tsh73 said:

if anyone beats it let me know, it's still possible if I recall.

I dunno about 8x8 but standard 7x6 is surely winnable by first player, if I remember what Wikipedia says.
I managed to win your program. Once. In about 20 tries

What language you wrote it? C?

I think I went with 8x8 because someone did point out to me that 7x6 was solved for first player, I thought that's because the board isn't symmetric like chess, the player going 2nd should be able to balance everything the player going first does, how can you do that with some odd amount board condition? So working on the game also became a sort of mathematical experiment.

I think I was originally coding this in SmallBASIC (not MS's) Interpreter only, then ported and made better in QB64 thus I can offer a compiled exe without revealing my secret AI (the secret is it is a little glitchy) that will be challenging to beat. When I was trying it out after digging up and posting, I found the AI announced it won when all squares were filled. I couldn't see it's win, glitch number 1 (Nice trick reminds me of Trump) ha! maybe I left that in as a prank; it is kinda funny! Another glitch I encountered was the board hanging after first round of a play again, like I forgot to clear something from first round(s) of play, and worse glitch was clicking a square and getting out of bounds error announced so something between mouse click conversion to column or row of board or not checking in bounds of array for board around top left area?


The timing of this post is a little off, I am sure I can translate to JB without any problem and I know I can make it better when I do, but alas at moment I am working on my Christmas Album and the rate I am going it will be next year's Christmas, ;-)) Just finishing up a Word Search Puzzle builder, you give it a list of words, it makes a puzzle in seconds instead of hours now. Imagine the list of all the Elements, 118 words, in a 30x30 in under a minute!

* if you can win, do it

* if you should block (3 in a row, 4th coming), do it

* else select possible column at random.

Yes, the first 2 were priority 1 and 2, win or spoil opponent's win, then you go looking to make 3's or spoil opponent's making of 3's.
Then 2's, with 2's I don't think you have room for completely random option.

The thing to do first is teach AI what a win looks like for either opponent. You need that anyway to tell if a winning move was made.

[B+]

Oh hey, just had a thought: must have a game recorder like in chess programs to debrief after wins and losses.

That most definitely would be my first priority in next version. I think a notation system is simply recording which column a player played a chip, 1 to 8, (no way am I working a game already solved) and a slightly better one would include for us brain damaged humans what column height that chip went to.

I wonder if anyone has analysed boards 4x4 up to 8x8 for what is solvable and what is not. I say, odd numbers favor 1st player.

[code]

To B+ : I won one time...

Your program looks also good.

Bye

[B+]

Dec 6, 2020 22:07:38 GMT code said:

To B+ : I won one time...

Your program looks also good.

View Attachment

Bye

Thanks for your report and congratulations. If I recall there was a certain weakness or trick you could repeat.

Did you run into any execution errors when playing?

[B+]

This makes me smile

[Rod]

In defence of my AI it is an attempt at min - max strategy. It is supposed to look one move ahead and establish the biggest winner, lowest losing move. I just haven't coded it right. But since the interface is pretty I still like it, and it lets me win!

[B+]

That interface is pretty, maybe I will barrow

[tsh73]

couple of thoughts
* leave some indicator of computer's last move (may be border)
so we at least see where computer win :)
* decouple solving part from drawing part, so we can pitch AIs against one another ;)

---

EDIT last move indicator - done, kind of
(also some bug fixed where first needed defense stopped looking for win)
'1. Allow for standard 7x6 field
'2. try to fix AI so it block dangerous points
'3. dismantled AI instead
'4. leave border after AI move
numCols=8:numRows=7
numCols=7:numRows=6
'numCols=5:numRows=4    'for debug
cs=60 'cellSize
offset=20
human=1
computer=2
'word$("blue yell",player)

' nomainwin
   ' find how much whitespace the windows scheme is taking
   ' Anatoly's tip
   WindowWidth = 200
   WindowHeight = 200
   open "Ajusting..." for graphics_nf_nsb as #1
   #1, "home ; down ; posxy w h"
   w=200-2*w : h = 200-2*h
   close #1


   ' setup a  520 x 480 graphics view
   ' the graphic box borders are just outside the window edge
   ' the playing area is 8x7 60x60 pixels ie 480x420
   g.w=cs*numCols
   g.h=cs*numRows
   WindowWidth  = g.w+w+2*offset
   WindowHeight = g.h+h+2*offset
   UpperLeftX   = (DisplayWidth-WindowWidth)/2
   UpperLeftY   = (DisplayHeight-WindowHeight)/2
   graphicbox #1.g, offset,offset,g.w+2,g.h+2
   open "Connect4" for window_nf as #1
   print #1, "trapclose [quit]"
   #1.g "down ; font consolas 16 bold"
   #1.g "backcolor darkblue ; color white"
   'visible drawing coordinates are 0 to 419 ie 420 pixels
   'draw our game graphics
   r=255
   g=128
   b=0
   For x = cs to 0 Step -1
       #1.g "color ";r;" ";g;" ";x
       #1.g "place 0 0 ; box ";x;" ";x
       r = r-1
       g = g-1
   Next
   #1.g "place 29 29 ; backcolor white ; circlefilled 24"
   #1.g "getbmp whit 0 0 60 60"
   r=0
   g=128
   b=255
   #1.g "size 2"
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       b=b-1
   next
   #1.g "getbmp blue 0 0 60 60"
   r=128
   g=255
   b=50
   for x=0 to 24
       #1.g "color ";r;" ";g;" ";b
       #1.g "place 29 29 ; circle ";x
       g=g-4
       r=r-1
   next
   #1.g "getbmp yell 0 0 60 60"

   'draw the board
   for i= 0 to numCols
       for j= 0 to numRows
           x=cs*i
           y=cs*j
           #1.g "drawbmp whit ";x;" ";y
       next
   next
   #1.g "color red"
   dim c(numCols,numRows)  '0-7 0-6 8x7 1= human 2= computer 0= free
   dim risk(numCols*numRows,4) 'cell risk/value c,r,risk,value
   dim d(8,2)  'delta x,y in 8 directions
   pi=acs(-1)
   for i = 1 to 8
       a=(i-1)*pi*2/8
       d(i,1)=int(1.5*cos(a))
       d(i,2)=int(1.5*sin(a))
   next


   [human]
   'are there moves left?
   nPossible=0
   for c = 0 to numCols-1
       if c(c,0)=0 then nPossible=nPossible+1
   next
   if nPossible=0 then
           notice "Draw (no moves)" : goto [quit]
   end if

   #1.g "when leftButtonDown [leftclick]"
   wait

   'check the column
   [leftclick]
   c=int(MouseX/cs)
   if c(c,0)>0 then wait

   player=human
   gosub [drop]
   gosub [chkWin]
   if result$<>"" then
       notice "Human Wins" : goto [quit]
   end if

   [computer]
   redim risk(1000,4)
   plays=0
   #1.g "when leftButtonDown"
   'check for win, required blocking move, or offensive play
   'check each cell and cast a ray in eight directions
   '(3)nope, only check each column and get next cell in that row
   nPossible=0
   shouldBlock$=""
   for c= 0 to numCols-1
       '--for r= 0 to numRows-1
       'get r as playable cell (c,r)
       r=0
       while c(c,r)=0 and r<numRows-1
           r=r+1
       wend
       if c(c,r)>0 then r=r-1
       if r<0 then [nextC]    'filled column
       print c;" ";r,
       'check for win
       player=computer
       gosub [chkWin]
       if result$<>"" then
           'draw computer token at (r,c)
           gosub [drop]
           'say computer won
           notice "Computer Wins" : goto [quit]
       end if
       'check for possible loose
       player=human
       gosub [chkWin]
       if result$<>"" then
           'computer should move at (r,c)
           '#1.g "drawbmp ";word$("blue yell",computer);" ";c*cs;" ";r*cs
           'c(c,r)=computer
           'exit for - no! we couls win next column!
           shouldBlock$="";c
       end if
       'else we just have playable cell. How to choose?
       'let for now do random select
       print "col ";c;" is possible"
       cc(nPossible)=c
       nPossible=nPossible+1
       'next
[nextC]
   next

   if shouldBlock$<>"" then    'should block
       print "should block at ";shouldBlock$
       pc=val(shouldBlock$)
   else
       if nPossible=0 then
           notice "Draw (no moves)" : goto [quit]
       end if
       'select next if nothing urgent
       n=int(rnd(0)*nPossible)
       pc=cc(n)
       print "col ";pc;" is selected"
   end if
   print

   c=pc
   'find how far we are falling
   player=computer
   'redraw last piece without border
   gosub [drop]

   goto [human]


   [quit]
   close #1
   end

[drop]    'by player
   'find how far we are falling
       'redraw last piece without border
   #1.g lastCmd$
   r=0
   while c(c,r)=0 and r<numRows-1
       #1.g "drawbmp whit ";c*cs;" ";(r-1)*cs
       #1.g "drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
       r=r+1
       timer 56,[g]
       wait
       [g]
       timer 0
   wend
   if c(c,r)>0 then r=r-1
   #1.g "drawbmp whit ";c*cs;" ";(r-1)*cs
   lastCmd$="drawbmp ";word$("blue yell",player);" ";c*cs;" ";r*cs
   #1.g lastCmd$
   #1.g "place ";c*cs+1;" ";r*cs+1;";box ";(c+1)*cs-1;" ";(r+1)*cs-1
   c(c,r)=player

return

[chkWin]    'by player
   'will player win by putting token at (r,c)?
   result$=""
   for n= 1 to 8    'directions
       maxRun=0
       curRun=0
       for i= -3 to 3
           nc=c+i*d(n,1)    'next col, row
           nr=r+i*d(n,2)
           'if on field
           if not(nc>=0 and nc<numCols and nr>=0 and nr<numRows) then [ckipCell]
           'print i, nc,nr, c(nc,nr),c(nc,nr)=player, c(nc,nr)=player or (nc=c and nr=r)
           if c(nc,nr)=player or (nc=c and nr=r) then curRun=curRun+1 else curRun=0
           if curRun>3 then 'win
               result$="win"
               exit for
           end if
[ckipCell]
       next
       'print n, i, curRun
       if result$<>"" then exit for
   next
return



[B+]

Just out of curiosity what is wrong with same amount of rows and columns?

Bonus for 5 in row??

[tsh73]

Just out of curiosity what is wrong with same amount of rows and columns?

Rod's code had it 8x7, hardcoded
I got from Wikipedia that standard values is 7x8 EDIT 7x6
So I first introduced
numCols
numRows
and made sure (as far as I can tell) it works with different values.
So I run it with 8x8, and it works with no problem I saw.

Well, you either win or not. No reason for bonus.