Thick line with border

[tsh73]

Thick line with border
which overprints making look like real layers (kind of 3d)
I dunno.
Really inspired by this, I guess.
justbasiccom.proboards.com/thread/314/celtic-knot-challenge
I had an idea - I got something working
Now go on and use it for something

'Want to get: thick line with colored border follows the mouse
'(by drawing rotated line with colored points)
nomainwin

open "Draw with a mouse" for graphics_nsb_nf as #gr
#gr "down; home; posxy cx cy"
#gr "trapclose [quit]"
#gr "when mouseMove [move]"
#gr "size 3"
x0=cx:y0=cy
timer 1, [tick]

d = 15

'#gr

wait
[tick]
   'move x0 y0 into x y direction
   dx=x-x0
   dy=y-y0
   a = atan2(dx,dy)
   r=sqr(dx^2+dy^2)
   if r<2 then wait
   ''else
   x0=x0+dx/r'/2   'divide for smoother things (but slower)
   y0=y0+dy/r'/2
   #gr "north; turn ";a'+90
   #gr "color black"
   #gr "place ";x0;" ";y0
   #gr "go ";d
   #gr "color green"
   #gr "posxy xx yy"
   #gr "set ";xx;" ";yy
   #gr "color black"
   #gr "go ";-2*d
   #gr "color green"
   #gr "posxy xx yy"
   #gr "set ";xx;" ";yy
wait

[move]
   x=MouseX
   y=MouseY
'    #gr "color red"
'    #gr "set ";x;" ";y
WAIT


[quit]
close #gr
end

function atan2(x,y) 'returns 0..360 degrees
if abs(x)<0.001 then atan2 = 90+(y<0)*180 : exit function
   pi = 3.1415925
   tan = y/x
   atn = atn(tan)
select case
   case x>0 and y>0
       atan2 = atn/pi*180
   case x<=0
       atn = atn + pi
       atan2 = atn/pi*180
   case else
       atn = atn + 2*pi
       atan2 = atn/pi*180
end select
end function



[B+]

I wonder if you lead with a black semi-circle with yellow edge, you could avoid splits in your race track.

[tsh73]

Nov 26, 2020 5:46:56 GMT B+ said:

I wonder if you lead with a black semi-circle with yellow edge, you could avoid splits in your race track.

May be
nearest thing to semi-circle is "PieFilled" command
And it should point to movement direction
And to make only outer edge will involve drawing it manually (more maths)

Meanwhile I got smooth race track by fitting it over Lissajous curve





'Want to get: thick line with colored border follows the mouse
'(by drawing rotated line with colored points)
nomainwin

open "Draw with a mouse" for graphics_nsb_nf as #gr
#gr "down; home; posxy cx cy"
#gr "trapclose [quit]"
#gr "when mouseMove [move]"
#gr "size 3"
x0=cx:y0=cy
'timer 1, [tick]

d = 15
pi=acs(-1)

x0=.8*cx*cos(3*phi)+cx
y0=.8*cy*sin(2*phi)+cy

for phi = 0 to 2*pi step 0.001
   x=.8*cx*cos(3*phi)+cx
   y=.8*cy*sin(2*phi)+cy
   '#gr "set ";x;" ";y
   'print phi, "set ";x;" ";y
   do
       gosub [tickSub]
   loop until r<2
next

wait
[tick]
   gosub [tickSub]
   wait

[tickSub]
   'move x0 y0 into x y direction
   dx=x-x0
   dy=y-y0
   a = atan2(dx,dy)
   r=sqr(dx^2+dy^2)
   if r<2 then return
   ''else
   x0=x0+dx/r'/2   'divide for smoother things (but slower)
   y0=y0+dy/r'/2
   #gr "north; turn ";a'+90
   #gr "color black"
   #gr "place ";x0;" ";y0
   #gr "go ";d
       #gr "up; go 3; down"
   #gr "color green"
   #gr "posxy xx yy"
   #gr "set ";xx;" ";yy
       #gr "up; go -3; down"
   #gr "color black"
       '#gr "up"
   #gr "go ";-2*d
       #gr "up; go -3; down"
   #gr "color green"
   #gr "posxy xx yy"
   #gr "set ";xx;" ";yy
return

[move]
   x=MouseX
   y=MouseY
'    #gr "color red"
'    #gr "set ";x;" ";y
WAIT


[quit]
close #gr
end

function atan2(x,y) 'returns 0..360 degrees
if abs(x)<0.001 then atan2 = 90+(y<0)*180 : exit function
   pi = 3.1415925
   tan = y/x
   atn = atn(tan)
select case
   case x>0 and y>0
       atan2 = atn/pi*180
   case x<=0
       atn = atn + pi
       atan2 = atn/pi*180
   case else
       atn = atn + 2*pi
       atan2 = atn/pi*180
end select
end function



[tsh73]

Beating a dead horce
(still trying to avoid using math for orthogonal lines)

This #gr "place ";xx0;" ";yy0
#gr "up; go ";4*i;"; down"
happened to be MUCH better then 7 times
#gr "up; go 4; down"

'Want to get: thick line with colored border follows the mouse
'(by drawing rotated line with colored points)
'rainbow version
nomainwin
dim c$(7)
data "red", "255 127 0", "yellow", "green", "cyan", "blue", "127 0 255"
for i = 1 to 7: read tmp$: c$(i)=tmp$: print c$(i): next
'end


open "Rainbow?" for graphics_nsb_nf as #gr
#gr "down; home; posxy cx cy"
#gr "trapclose [quit]"
#gr "when mouseMove [move]"
#gr "size 4"
x0=cx:y0=cy
'timer 1, [tick]

d = 15
pi=acs(-1)

x0=.8*cx*cos(3*phi)+cx
y0=.8*cy*sin(2*phi)+cy

for phi = 0 to 2*pi step 0.001
   x=.8*cx*cos(3*phi)+cx
   y=.8*cy*sin(2*phi)+cy
   '#gr "color black"
   '#gr "set ";x;" ";y
   'print phi, "set ";x;" ";y
   do
       gosub [tickSub]
   loop until r<2
next

wait
[tick]
   gosub [tickSub]
   wait

[tickSub]
   'move x0 y0 into x y direction
   dx=x-x0
   dy=y-y0
   a = atan2(dx,dy)
   r=sqr(dx^2+dy^2)
   if r<2 then return
   ''else
   x0=x0+dx/r'/2   'divide for smoother things (but slower)
   y0=y0+dy/r'/2
   #gr "place ";x0;" ";y0
   #gr "north; turn ";a'+90
   #gr "up; go -16; down"
   #gr "posxy xx0 yy0"
   for i = 1 to 7
       #gr "color ";c$(i)
       #gr "place ";xx0;" ";yy0
       #gr "up; go ";4*i;"; down"
       #gr "posxy xx yy"
       #gr "set ";xx;" ";yy
   next
'wait
return

[move]
   x=MouseX
   y=MouseY
'    #gr "color red"
'    #gr "set ";x;" ";y
WAIT


[quit]
close #gr
end

function atan2(x,y) 'returns 0..360 degrees
if abs(x)<0.001 then atan2 = 90+(y<0)*180 : exit function
   pi = 3.1415925
   tan = y/x
   atn = atn(tan)
select case
   case x>0 and y>0
       atan2 = atn/pi*180
   case x<=0
       atn = atn + pi
       atan2 = atn/pi*180
   case else
       atn = atn + 2*pi
       atan2 = atn/pi*180
end select
end function