Parabolic rescue.

[honkytonk]

Hello,
Who could put me this damn formula in this interface

I think "z" is --->"y"
"v0" is the initial velocity.
"z0" is the height from which the projectile is fired.
"alpha" is--->: "theta" (optional).
The problem: I don't know what to do with (t).
For mass, normally; it is in the initial speed (e=1/2 m*v^2), so you don't have to worry about it???
Thank you for.


    NOMAINWIN
    mapw=650: maph= 400
   WindowWidth=mapw+15: WindowHeight=maph+40
   UpperLeftX = 10: UpperLeftY = 20
   TEXTBOX #w.v0, 70, 20, 60, 25
   TEXTBOX #w.theta, 215, 20, 60, 25
  ' TEXTBOX #w.m, 70, 55, 80, 25
   TEXTBOX #w.d, 205, 55, 120, 25
   BUTTON #w.go, "Go!", [go], UL, 485, 20, 40, 25
  GRAPHICBOX #w.g, 5, 5, mapw, maph
   OPEN "Help" FOR window_nf AS #w
   #w, "TRAPCLOSE [closeHelp]"
   #w.g, "down;fill darkgreen;color white;backcolor darkgreen;size 2"
   #w.g, "font courrier 12 bold"
   #w.v0, "!font courrier 12 bold": #w.v0, "???" '<---Put your valor here
   #w.theta, "!font courrier 12 bold": #w.theta, "???" '<---Put your valor here
   '#w.m, "!font courrier 12 bold": #w.m, "0.1"
   #w.d, "!font courrier 12 bold"
   #w.g, "place 10 30": #w.g, "\v0 --->": #w.g, "place 130 30": #w.g, "\Theta --->"
  ' #w.g, "place 10 70": #w.g, "\m --->":
   #w.g, "place 160 70": #w.g, "\d --->"
   #w.g, "place 295 30": #w.g, "\<--- Change and Go --->"
   #w.g, "flush"
 '  m = 0.1 '1  'fixed mass of stone in kg. 0.1
 '  A = 0.002  'csa of stone in m^2.
 '  g = 9.81  'acc'n of gravity m^s2.
 '  D = 1.2   'density of air.
  ' Cd = 0.75   'allows for the shape.
  ' v = 0.005 '60  'release velocity in m/s.
  ' theta = 30  'release angle in degrees,
  ' theta =theta /180 *3.14159265 '     ... changed to radians.
  ' y = 0  'initial vertical height.
 '  vy = v *cos( theta)  'initial vertical vel'y.
  ' x = 0  'initial horizontal position.
  ' vx = v *sin( theta) 'initial horizontal vel'y.
  ' t = 0   'initial time.             s
  ' dt = 0.001   'time interval between updates.
  ' wait
[go]
   #w.v0, "!contents? v0$": v0=val(v0$)
   #w.theta, "!contents? theta$": theta=val(theta$)
   theta=theta /180 *3.14159265
 ' #w.m, "!contents? m$": m=val(m$)
   t=0: y=0: x=0
 [fire]
    scan
  'Put the magic formula here
  'And what it takes to make it work the damned (t)
  'A million thanks
wait
 [closeHelp]
   CLOSE  #w
   END

The formula (clic on for zoom):

[tsh73]

Hello honkytonk
I found this (or very like this) formula on Wikipedia
en.wikipedia.org/wiki/Trajectory#Derivation_of_the_equation_of_motion
It has y instead of Z and has no z0 but it is really same formula.
And it calculates height (y or z, whatever) by X position.
It does not use "t" at all.

(if you need "t" you can get it from equation
x=v_x * t,
x you have, v_x is v0*cos(theta)
)

[honkytonk]

When we click on "A" it works, but it's reversed.
For "B" I can't seem to twist the formula.
Where to find the right parameters.

    NOMAINWIN
    mapw=900: maph= 400
   WindowWidth=mapw+15: WindowHeight=maph+40
   UpperLeftX = 10: UpperLeftY = 20
   TEXTBOX #w.v0, 70, 20, 60, 25
   TEXTBOX #w.theta, 215, 20, 60, 25
   TEXTBOX #w.z0, 70, 55, 80, 25
   TEXTBOX #w.d, 205, 55, 120, 25

   BUTTON #w.clear, "Clear", [clear], UL, 340, 55, 60, 25
   BUTTON #w.A, "A", [A], UL, 445, 20, 40, 25
   BUTTON #w.B, "B", [B], UL, 445, 60, 40, 25
  GRAPHICBOX #w.g, 5, 5, mapw, maph
   OPEN "Help" FOR window_nf AS #w
   #w, "TRAPCLOSE [closeHelp]"
 [clear]
   #w.g, "down;fill darkgreen;color white;backcolor darkgreen;size 2"
   #w.g, "font courrier 12 bold"
   #w.v0, "!font courrier 12 bold": #w.v0, "20" '<---Put your valor here
   #w.theta, "!font courrier 12 bold": #w.theta, "20" '<---Put your valor here
   #w.z0, "!font courrier 12 bold": #w.z0, "1"
   #w.d, "!font courrier 12 bold"
   #w.g, "place 10 30": #w.g, "\v0 --->": #w.g, "place 130 30": #w.g, "\Theta --->"
   #w.g, "place 10 70": #w.g, "\z0 --->"
   #w.g, "place 160 70": #w.g, "\d --->"
   #w.g, "place 280 30": #w.g, "\<--- Change and --->"
   #w.g, "place 490 30": #w.g, "\<-- y=0 - (g*theta) /(v0^2*2)*x^2+x*tan(theta)+200"
   #w.g, "place 490 70": #w.g, "\<-- y=(g*theta) /(v0^2*2)*x^2+x*tan(theta)+200"
   #w.g, "flush"
   g = 9.81
   wait
[A]
  gosub [calca]
  gosub [pause]
  #w.theta, "40"
  gosub [calca]
  gosub [pause]
  #w.theta, "70"
  gosub [calca]
  gosub [pause]
  #w.v0, "10"
  gosub [calca]
  gosub [pause]
  #w.v0, "30"
  gosub [calca]
wait
[calca]
  gosub [init]
 [AA]
  ' y=0 - (g*sec^2*theta) /(v0^2*2)*x^2+x*tan(theta)
  y=0 - (g*theta) /(v0^2*2)*x^2+x*tan(theta)+z '(presque bon   '
  gosub [display]
  x=x+0.5
   if y >0 then goto [AA]
   return
 wait
 [B]
  gosub [calcb]
  gosub [pause]
  #w.z0, "0"
  gosub [calcb]
  gosub [pause]
  #w.v0, "50"
  gosub [calcb]
  gosub [pause]
  #w.theta, "70"
  gosub [calcb]
  gosub [pause]
  #w.z0, "1"
  gosub [calcb]
 wait
 [calcb]
   gosub [init]
 [BB]
   scan
  ' y=0 - (g*sec^2*theta) /(v0^2*2)*x^2+x*tan(theta)
    y=(g*theta) /(v0^2*2)*x^2+x*tan(theta)'+z
   gosub [display]
   x=x+0.1
   if y <400 then goto [BB]
 return
 wait
 [init]
   #w.v0, "!contents? v0$": v0=val(v0$)
   #w.theta, "!contents? theta$": theta=val(theta$)
   theta=theta /180 *3.14159265
   #w.z0, "!contents? z$": z=val(z$)
   y=0: x=0
 return
 [display]
   #w.g, "set ";x;" ";y
 return
 [pause]
    timer 800, [temps]
    wait
    [temps]
    timer 0
 return
 [closeHelp]
   CLOSE  #w
   END


[honkytonk]

It's work !!!


   
    NOMAINWIN
    mapw=900: maph= 550
   WindowWidth=mapw+15: WindowHeight=maph+40
   UpperLeftX = 10: UpperLeftY = 5
   TEXTBOX #w.v0, 70, 20, 60, 25
   TEXTBOX #w.theta, 215, 20, 60, 25
   TEXTBOX #w.d, 205, 55, 120, 25
   BUTTON #w.clear, "Clear", [clear], UL, 340, 55, 60, 25
   BUTTON #w.go, "Go", [go], UL, 445, 20, 40, 25
  GRAPHICBOX #w.g, 5, 5, mapw, maph
   OPEN "Help" FOR window_nf AS #w
   #w, "TRAPCLOSE [closeHelp]"
 [clear]
   #w.g, "down;fill darkgreen;color white;backcolor darkgreen;size 2"
   #w.g, "font courrier 12 bold"
   #w.v0, "!font courrier 12 bold": #w.v0, "285" '<---Put your valor here
   #w.theta, "!font courrier 12 bold": #w.theta, "45" '<---Put your valor here
  ' #w.z0, "!font courrier 12 bold": #w.z0, "1"
   #w.d, "!font courrier 12 bold"
   #w.g, "place 10 30": #w.g, "\v0 --->": #w.g, "place 130 30": #w.g, "\Theta --->"
  ' #w.g, "place 10 70": #w.g, "\z0 --->"
   #w.g, "place 160 70": #w.g, "\d --->"
   #w.g, "place 280 30": #w.g, "\<--- Change and --->"
   #w.g, "place 490 30": #w.g, "\<-- y=0 - (g*theta) /(v0^2*2)*x^2+x*tan(theta)+200"
   #w.g, "flush"
   g = 9.81
   wait
[go]
  gosub [calca]
  gosub [pause]
  #w.theta, "70"
  gosub [calca]
  gosub [pause]
  #w.theta, "75"
  gosub [calca]
  wait
wait
[calca]
  gosub [init]
  v0=v0/10
 [AA]
  y=0 - (g*theta) /(v0^2*2)*x^2+x*tan(theta)'+1 '(presque bon
  y=549-y
 ' y=int(Y/3):x=int(x/3)
  gosub [display]
  x=x+0.1
  ' if y >0 then goto [AA]
  if y <550 then goto [AA]
   return
 wait

 [init]
   #w.v0, "!contents? v0$": v0=val(v0$)
   #w.theta, "!contents? theta$": theta=val(theta$)
   theta=theta /180 *3.14159265
   y=0: x=0
 return
 [display]
   #w.g, "set ";x;" ";y
 return
 [pause]
    timer 800, [temps]
    wait
    [temps]
    timer 0
 return
 [closeHelp]
   CLOSE  #w
   END



[honkytonk]

It's not good yet.
With v0 constant, the projectile falls further for 50°, 60°, 65° than for 45°.
This is not normal, the maximum range is 45°

[tsh73]

Where cos() have gone?
Looking at acceleration g multiplied by angle theta really hutrs me.

[tsh73]

Ok I restored missed cosine
and tweak a fiew things as well
Now button Go draws single trajectory, while GoGo draws a series
Also it shows distance and makes kind of log (until you press Clear)

And it is real simmetrical parabola,
and angles (45+a) and (45-a) - like 25 and 65 - will end in same point.
And 45 gives maximum distance.
'Simplified thing
'no air resistance

NOMAINWIN
mapw=900: maph= 550
   WindowWidth=mapw+15: WindowHeight=maph+40
   UpperLeftX = 10: UpperLeftY = 5
   TEXTBOX #w.v0, 70, 20, 60, 25
   TEXTBOX #w.theta, 215, 20, 60, 25
   TEXTBOX #w.d, 205, 55, 120, 25
   BUTTON #w.clear, "Clear", [clear], UL, 340, 55, 60, 25
   BUTTON #w.go, "Go", [go1], UL, 445, 20, 40, 25
   BUTTON #w.go, "GoGo", [go], UL, 445, 55, 60, 25
   GRAPHICBOX #w.g, 5, 5, mapw, maph

   OPEN "Help" FOR window_nf AS #w
   #w, "TRAPCLOSE [closeHelp]"

[init0]
fnt$="font courier 10 bold"
'fnt$="font courier 11 bold"
   #w.g, "down;fill darkgreen;color white;backcolor darkgreen;size 2"
xpos=520:ypos=70
#w.g, fnt$
#w.v0, "!";fnt$
#w.theta, "!";fnt$
#w.d, "!";fnt$
   g = 9.81
pi=acs(-1)
scale = 0.1 'meters to pixels
dx=1

[clear]
   #w.g, "down;fill darkgreen;color white;backcolor darkgreen;size 2"
#w.v0, "285" '<---Put your valor here
#w.theta, "45" '<---Put your valor here
  '#w.z0, "1"
   #w.g, "place 10 30": #w.g, "\v0 --->": #w.g, "place 130 30": #w.g, "\Theta --->"
  ' #w.g, "place 10 70": #w.g, "\z0 --->"
   #w.g, "place 20 70": #w.g, "\scale = ";scale
   #w.g, "place 160 70": #w.g, "\d --->"
   #w.g, "place 280 30": #w.g, "\<--- Change and --->"
#w.g, "font arial 10 bold"
#w.g, "place 490 30": #w.g, "\<-- y=0 - g / (2*(v0*cos(theta))^2)*x^2 + tan(theta)*x"
#w.g, fnt$
   #w.g, "flush"
#w.d, ""
xpos=520:ypos=70
wait

[go]
for a = 15 to 75 step 15
#w.theta, a
gosub [calca]
msg$="v=";v0;" a=";a;" d=";d
#w.g, "place ";xpos;" ";ypos
ypos=ypos+25
#w.g, "\";msg$
gosub [pause]
next
wait

[go1]
  gosub [calca]
msg$="v=";v0;" a=";a;" d=";d
#w.g, "place ";xpos;" ";ypos
ypos=ypos+25
#w.g, "\";msg$
wait

[calca]
gosub [init]
do
x=x+dx'0.1
y = 0 - g / (2*(v0*cos(theta))^2)*x^2 + tan(theta)*x
gosub [display]
loop until y < 0
d=x
#w.d, d 'distance
return

[display]
   #w.g, "set ";x*scale;" ";maph-y*scale
return

[init]
   #w.v0, "!contents? v0$": v0=val(v0$)
   #w.theta, "!contents? a$": a=val(a$)
   theta=a /180 *pi
   y=0: x=0
return

[pause]
    timer 800, [temps]
    wait
    [temps]
    timer 0
return

[closeHelp]
   CLOSE  #w
   END



[honkytonk]

It's perfect, thank you véry much.