What's going on with my painting ?

I have no idea what are you up to
but
matr(1,x)=x: matr(2,x)=y
stores ONE last point for any given X on a picture.
(so any X have no more then ONE point. If you move back and forth, only last one is stored)

If you want (??) to store points in array you better use current point number, P, like in

   nomainwin
    haut=200: larg=150
   WindowWidth = 205: WindowHeight = 350
   UpperLeftX = 100: UpperLeftY = 20
   STATICTEXT #w.pp, "N Data", 5, 10, 70, 25
   TEXTBOX  #w.p, 85, 10, 60, 25
   BUTTON #w.new, "New ", [new], UL, 155, 10, 40, 20
   BUTTON #w.go, "by array ", [drawback], UL, 10, 40, 80, 20
   BUTTON #w.gogo, "by chains ", [chain], UL, 100, 40, 80, 20
   STATICTEXT #w.tx, "Clic and move", 20, haut +80, 150, 25
       GRAPHICBOX #w.m 10, 70, larg, haut
   OPEN "Test" FOR window_nf AS #w
   #w, "TRAPCLOSE [closetest]"
 [new]
   #w.p, ""  '
    p=0: pl=0: x$="": y$=""
    'dim matr(2,haut+2)
    dim matr(2,10000)'big number of points
   #w.m  "down;fill darkgreen; color white;size 1"
   #w.m, "when leftButtonMove [keepdraw]"
   #w.m, "size 2"
   #w.tx, "!font courrier 14": #w.pp, "!font courrier 14"
   wait
   [keepdraw]
   x=MouseX: y= MouseY
    p=p +1: #w.p, str$(p)
    matr(1,p)=x: matr(2,p)=y
    x$=x$+str$(x)+" ": y$=y$+str$(y)+" "
    #w.m, "set ";matr(1,p);" ";matr(2,p) 'datas in box sure
 wait
 [drawback]
  #w.m  "down;fill darkred; color yellow;size 2"
  for i=1 to p
        #w.m, "set ";matr(1,i);" ";matr(2,i)
  next i
  wait
  [chain]
    #w.m  "down;fill darkpink; color black;size 2"
    for t=1 to p
      #w.m, "set ";val(word$(x$,t));" ";val(word$(y$,t))
    next t
  wait
 [closetest]
   CLOSE  #w
   END


What I would like is the whole matrix (the whole window with the polygon drawn in it) and that in an array of the size of the window.

"size of the window" is rectangular (2d) array
dim matr(larg, haut)
So you either have a pont at (x,y) so matr(x,y)=1
or not - then matr(x,y) stays 0
Like this
nomainwin
    haut=200: larg=150
   WindowWidth = 205: WindowHeight = 350
   UpperLeftX = 100: UpperLeftY = 20
   STATICTEXT #w.pp, "N Data", 5, 10, 70, 25
   TEXTBOX  #w.p, 85, 10, 60, 25
   BUTTON #w.new, "New ", [new], UL, 155, 10, 40, 20
   BUTTON #w.go, "by array ", [drawback], UL, 10, 40, 80, 20
   BUTTON #w.gogo, "by chains ", [chain], UL, 100, 40, 80, 20
   STATICTEXT #w.tx, "Clic and move", 20, haut +80, 150, 25
       GRAPHICBOX #w.m 10, 70, larg, haut
   OPEN "Test" FOR window_nf AS #w
   #w, "TRAPCLOSE [closetest]"
 [new]
   #w.p, ""  '
    p=0: pl=0: x$="": y$=""
    dim matr(larg, haut)  'square matrix, dimension larg x haut (width height)
   #w.m  "down;fill darkgreen; color white;size 1"
   #w.m, "when leftButtonMove [keepdraw]"
   #w.m, "size 2"
   #w.tx, "!font courrier 14": #w.pp, "!font courrier 14"
   wait
   [keepdraw]
   x=MouseX: y= MouseY
   if x<0 or x>larg or y <0 or y > haut then wait  'ot ot falls out of matrix
    matr(x,y)=1
    x$=x$+str$(x)+" ": y$=y$+str$(y)+" "
    #w.m, "set ";x;" ";y 'datas in box sure
        p=p +1: #w.p, str$(p)
 wait
 [drawback]
  #w.m  "down;fill darkred; color yellow;size 2"
  for y=1 to haut
    for x=1 to larg
      if matr(x,y)<> 0  then
        #w.m, "set ";x;" ";y
      end if
    next x
  next y
  wait
  [chain]
    #w.m  "down;fill darkpink; color black;size 2"
    for t=1 to p
      #w.m, "set ";val(word$(x$,t));" ";val(word$(y$,t))
    next t
  wait
 [closetest]
   CLOSE  #w
   END


Wikipedia have some
en.wikipedia.org/wiki/Flood_fill

If you swap to JB's 'big brother' Liberty BASIC, you can call a dll easily for flood filling- it is very slow if you instead write your own routine in BASIC! JB code runs in LB and a lot of useful other things are added- and it is free with a few things disabled until you buy a licence.
Everything you've learned in JB works exactly the same in LB
See www.diga.me.uk/floodFill2.html for an example on my LB webpages.

Also, I know a font called 'Courier' but not 'courrier'.

You are putting a lot of random dots into the array and onto screen then expecting them to be "joined" without putting in any code to do that. So you must draw the "shape" as lines then fill in between lines. It is a lot more complicated than your code attempts and it will be very slow to draw.

There is some polygon filling code in the archives. One of the "old" gurus, UncleBen or AltBas.

Here is simple recursive implementation
along Wikipedia
en.wikipedia.org/wiki/Flood_fill
Stack-based recursive implementation (four-way)

size set to 1 - we should see where paint leaks
edge is drawn with matr(x,y) =1
Area is filled with matr(x,y) =2
"by array" button draws points where matr(x,y) =1 and resets those points with matr(x,y) =2 to matr(x,y) =0
so it paint leaked we could press "by array" and fix (patch) gaps in the contour.



nomainwin
global larg, haut
    haut=200: larg=150
   WindowWidth = 305: WindowHeight = 370
   UpperLeftX = 300: UpperLeftY = 20
   STATICTEXT #w.pp, "N Data", 5, 10, 70, 25
   TEXTBOX  #w.p, 85, 10, 60, 25
   BUTTON #w.new, "New ", [new], UL, 155, 10, 40, 20
   BUTTON #w.sto, "Stop ", [stop], UL, 210, 10, 40, 20
   BUTTON #w.go, "by array ", [drawback], UL, 10, 40, 80, 20
   STATICTEXT #w.tx, "Clic and move for polygon", 10, haut +80, 230, 25
   STATICTEXT #w.txa, "And Try", 10, haut +100, 100, 25
   BUTTON #w.try, "Try ", [palpe], UL, 100, 40, 80, 25
       GRAPHICBOX #w.m 10, 70, larg, haut
   OPEN "Test" FOR window_nf AS #w
   #w, "TRAPCLOSE [closetest]"
 [new]
   #w.p, ""  '
    p=0: pl=0: x$="": y$=""
     dim matr(larg+1, haut+1)
   #w.m  "down;fill darkgreen; color white;size 1"
   #w.m, "when leftButtonMove [keepdraw]"
   '#w.m, "size 2" 'leaves gaps!!!
   #w.tx, "!font courrier 14": #w.txa, "!font courrier 14"
   #w.pp, "!font courrier 12": #w.try, "!font courrier 12 bold"
   wait
[keepdraw]
x=MouseX: y= MouseY
if x<0 or x>larg or y <0 or y > haut then wait 'or it falls out of matrix
matr(x,y)=1
#w.m, "set ";x;" ";y 'datas in box sure
p=p +1: #w.p, str$(p)
wait
[drawback]
'#w.m "down;fill darkred; color yellow;size 2"
#w.m "cls"
#w.m "down;fill darkred; color yellow" 'no size 2
for y=1 to haut
for x=1 to larg
if matr(x,y)= 1 then
#w.m, "set ";x;" ";y
end if
if matr(x,y)= 2 then matr(x,y)= 0 'so we can refill it
next x
next y
wait

sub FloodFill x,y 'simple recursive implementation
'along Wikipedia
'https://en.wikipedia.org/wiki/Flood_fill
'Stack-based recursive implementation (four-way)
SCAN
'global larg, haut - w, h
if x <0 or x > larg or y <0 or y >haut then exit sub
if matr(x,y) <> 0 then exit sub
'else set colored
matr(x,y) =2 'fills matr array - breaks it?
#w.m, "set ";x;" ";y
call FloodFill x+1,y
call FloodFill x,y+1
call FloodFill x-1,y
call FloodFill x,y-1

end sub
  '--------------------
 [palpe]
   #w.m, "when mouseMove"
   #w.m  "down;fill darkred"
'recursive flood fill
#w.m, "down;color cyan;size 1"
call FloodFill 1,1

wait

 [pause]
       timer 2, [temps]
       wait
       [temps]
       timer 0
 return
 [closetest]
   CLOSE  #w
   END