crab sprite game

[tsh73]

Recreating thing created in Scratch2 in JB.
(only thing - Scratch had cat and star instead of caveman and pizza. And better undersea BG
And I did not made animation in Scratch, though sprites had frames)
Indeed things like "when hit the edge change direction" is hard to beat...
But without ability to copy paste between projects Scratch looks like a toy for me
'kind of game
'tsh73 Jun 2019
nomainwin

WindowWidth = 640
WindowHeight = 480
UpperLeftX=1
UpperLeftY=1

sprPath$="sprites\" 'from jb folder
'sprPath$="C:\progs\Just BASIC v1.01\SPRITES\" 'from other folder - absolute path

open "Crab game" for graphics_nsb_nf as #gr
#gr "trapclose [quit]"
#gr "fill white; flush; down"
#gr "home; posxy cx cy"
#gr "setfocus"

loadbmp "UnderTheSea", sprPath$+"BG3.bmp"
#gr "background UnderTheSea"

dim crabVx(3),crabVy(3)
crabVx(1)=4:crabVy(1)=3
crabVx(2)=5:crabVy(2)=4
crabVx(3)=6:crabVy(3)=5
loadbmp "crab1", sprPath$+"crab1.bmp"
loadbmp "crab2", sprPath$+"crab2.bmp"
loadbmp "crab3", sprPath$+"crab3.bmp"
#gr "addsprite crab1 crab1 crab2 crab3"
#gr "cyclesprite crab1 1"
#gr "spritexy crab1 50 50";
#gr "spritemovexy crab1 ";crabVx(1);" ";crabVy(1)
#gr "spriteorient crab1 mirror"
crabW=61
crabH=51
#gr "addsprite crab2 crab1 crab2 crab3"
#gr "cyclesprite crab2 1"
#gr "spritexy crab2 -200 50";
'#gr "spritemovexy crab2 ";crabVx(2);" ";crabVy(2)
#gr "spriteorient crab2 mirror"
#gr "spritescale crab2 125"

#gr "addsprite crab3 crab1 crab2 crab3"
#gr "cyclesprite crab3 1"
#gr "spritexy crab3 -200 150";
'#gr "spritemovexy crab3 ";crabVx(3);" ";crabVy(3)
#gr "spriteorient crab3 mirror"
#gr "spritescale crab3 150"

loadbmp "cave1", sprPath$+"cave1.bmp"
loadbmp "cave2", sprPath$+"cave2.bmp"
#gr "addsprite cave cave1 cave2"
#gr "cyclesprite cave 1"
#gr "spritexy cave 550 400"
manW=43
manH=74
manV=7

loadbmp "pizza", sprPath$+"pizza.bmp"
#gr "addsprite pizza pizza"
#gr "spritexy pizza 300 200"
pizzaW=31
pizzaH=30

#gr "when mouseMove [Move]"
hp=10
points=0
msg$=space$(10)
#gr "font 20 bold"

timer 100, [nxt]
pizzaOff=0
hit=0
isRun=1

[nxt]
   if (hit=0) and isRun then
       #gr "spritexy? cave x y"
       d = sqr((toX-x)^2+(toY-y)^2)
       if d = 0 then d=1    'prevent div/0
       dx = (toX-x)/d*manV
       dy = (toY-y)/d*manV
       #gr "spritexy cave ";x+dx;" ";y+dy
       if dx <0 then
           #gr "spriteorient cave mirror";
       else
           #gr "spriteorient cave normal";
       end if
   end if

   #gr "spritecollides cave list$"
   if instr(list$, "pizza") then
       t2Return=time$("ms")+2000
       #gr "spritevisible pizza off"
       #gr "spritexy pizza -200 0"
       pizzaOff=1
       points=points+1
       if points=5 then    'crab2
           'release The Kraken
           px=int(rnd(0)*(2*cx-crabW))
           py=int(rnd(0)*(2*cy-crabH))
           #gr "spritexy crab2 ";px;" ";py
           #gr "spritemovexy crab2 ";crabVx(2);" ";crabVy(2)
       end if
       if points=10 then    'crab3
           px=int(rnd(0)*(2*cx-crabW))
           py=int(rnd(0)*(2*cy-crabH))
           #gr "spritexy crab3 ";px;" ";py
           #gr "spritemovexy crab3 ";crabVx(3);" ";crabVy(3)
       end if
   end if

   if pizzaOff and (time$("ms")>t2Return) then
       #gr "spritevisible pizza on"
       px=int(rnd(0)*(2*cx-pizzaW))
       py=int(rnd(0)*(2*cy-pizzaH))
       #gr "spritexy pizza ";px;" ";py
       pizzaOff=0
   end if

   if isRun and hit=0 then
       if instr(list$, "crab") then
           t2Return=time$("ms")+1000
           hit=1
           msg$="  Ouch!  "
                '1234567890
           hp=hp-1
           if hp <1 then'die
               isRun=0
               msg$="Game over!"
               #gr "spriteorient cave flip"
               #gr "spritemovexy cave 0 -3"
               #gr "cyclesprite cave 0"
           end if
       end if
   end if

   if isRun and hit and (time$("ms")>t2Return) then
       hit=0
       msg$=space$(10)
   end if


   #gr "spritexy? crab1 x y"
   crabVChanged=0
   if (x+crabW>2*cx ) or (x<0) then crabVx(1)=0-crabVx(1): crabVChanged=1
   if (y+crabH>2*cy ) or (y<0) then crabVy(1)=0-crabVy(1): crabVChanged=1
   if crabVChanged then
       #gr "spritemovexy crab1 ";crabVx(1);" ";crabVy(1)
       if crabVx(1) >0 then
           #gr "spriteorient crab1 mirror";
       else
           #gr "spriteorient crab1 normal";
       end if
   end if

   #gr "spritexy? crab2 x y"
   crabVChanged=0
   if (x+crabW>2*cx ) or (x<0) then crabVx(2)=0-crabVx(2): crabVChanged=1
   if (y+crabH>2*cy ) or (y<0) then crabVy(2)=0-crabVy(2): crabVChanged=1
   if crabVChanged then
       #gr "spritemovexy crab2 ";crabVx(2);" ";crabVy(2)
       if crabVx(2) >0 then
           #gr "spriteorient crab2 mirror";
       else
           #gr "spriteorient crab2 normal";
       end if
   end if

   #gr "spritexy? crab3 x y"
   crabVChanged=0
   if (x+crabW>2*cx ) or (x<0) then crabVx(3)=0-crabVx(3): crabVChanged=1
   if (y+crabH>2*cy ) or (y<0) then crabVy(3)=0-crabVy(3): crabVChanged=1
   if crabVChanged then
       #gr "spritemovexy crab3 ";crabVx(3);" ";crabVy(3)
       if crabVx(3) >0 then
           #gr "spriteorient crab3 mirror";
       else
           #gr "spriteorient crab3 normal";
       end if
   end if

   #gr "DRAWSPRITES"
   'stats
   #gr "place 0 0"
   #gr "\\";using("###",points)

   #gr "place 250 0"
   #gr "\\";msg$


   #gr "place 550 0"
   #gr "\\";using("###",hp)
wait

[Move]
   toX = MouseX
   if toX>2*cx-manW then toX=2*cx-manW
   toY = MouseY
   if toY>2*cy-manH then toY=2*cy-manH
wait

[quit]
   timer 0
   close #gr
end


[B+]

Hey, not bad!

Now I wonder what the sprites were originally used for?

[honkytonk]

10 for me, and you ?

[tsh73]

10 for me, and you ?

If that's about high score then I used to get 13
But I work on code
and yesterday I got to 3rd crab without losing a life...
Happened that I broke collision code in a process
*let my child (age 8) test it*
*she got bored after 18 points, 3 hp left*

Anyway. New version.
Visible changes:
* Character walks center to mouse, not top left to mouse
* When not walking character is not animated
* Big crabs does not walk off screen (so there is size stored for each crab)
* There is a bug with sprite scaling - collision code fires on much bigger area then it should
It is circumvented by using custom "intersect" routine, so big crabs are easier to avoid
(so I guess it is possible to run longer )
Invisible changes:
* There is a sub loadSprites (actually loads *one* sprite, consisting of several bitmap-frames)
* Sprite size are read from bitmap
* All repeated code (crab1 crab2 crab3) is rolled into loops.

---

EDIT
if they all are rolled into loops, why limit to 3 crabs?
*ka-BOOM!*
*evil laugh*

---

'kind of game
'tsh73 Jun 2019
nomainwin

WindowWidth = 640
WindowHeight = 480
UpperLeftX=1
UpperLeftY=1

sprPath$="sprites\" 'from jb folder
'sprPath$="C:\progs\Just BASIC v1.01\SPRITES\" 'from other folder - absolute path

open "Crab game" for graphics_nsb_nf as #gr
#gr "trapclose [quit]"
#gr "fill white; flush; down"
global cx, cy
#gr "home; posxy cx cy"
#gr "setfocus"

loadbmp "UnderTheSea", sprPath$+"BG3.bmp"
#gr "background UnderTheSea"

maxCrabs=6
dim crabVx(maxCrabs),crabVy(maxCrabs)
dim crabW(maxCrabs),crabH(maxCrabs)

call loadSprites "#gr", sprPath$, "crab1", "crab1 crab2 crab3", crabW, crabH

scale = 100
for i = 1 to maxCrabs
   sprName$="crab";i
   if i >1 then
       #gr "addsprite ";sprName$;" crab1 crab2 crab3"
   end if
   #gr "cyclesprite ";sprName$;" 1"
   #gr "spritexy ";sprName$;" -200 50"    'offscreen
   #gr "spriteorient ";sprName$;" imirror"
   #gr "spritescale ";sprName$;" ";scale
   crabVx(i)=4*scale/100
   crabVy(i)=3*scale/100
   crabW(i)=crabW*scale/100
   crabH(i)=crabH*scale/100
   scale=int(scale*1.25)
next

#gr "spritemovexy crab1 ";crabVx(1);" ";crabVy(1)
#gr "spritexy crab1 50 50";
#gr "spriteorient crab1 mirror";

call loadSprites "#gr", sprPath$, "cave", "cave1  cave2", manW, manH
#gr "spritexy cave 550 400"
manV=7

call loadSprites "#gr", sprPath$, "pizza", "pizza", pizzaW, pizzaH
#gr "spritexy pizza 300 200"

#gr "when mouseMove [Move]"
hp=10
points=0
ptsPerCrab=5
msg$=space$(10)
#gr "font 20 bold"

timer 100, [nxt]
pizzaOff=0
hit=0
isRun=1

[nxt]
   if (hit=0) and isRun then
       #gr "spritexy? cave x y"
       d = sqr((toX-x)^2+(toY-y)^2)
       if d < manV then 'do nothing:stay still
       else 'do walk
           dx = (toX-x)/d*manV
           dy = (toY-y)/d*manV
           #gr "spritexy cave ";x+dx;" ";y+dy
           #gr "cyclesprite cave 1 once"
           if dx <0 then
               #gr "spriteorient cave mirror";
           else
               #gr "spriteorient cave normal";
           end if
       end if
   end if

   #gr "spritecollides cave list$"
   if instr(list$, "pizza") then
       t2Return=time$("ms")+2000
       #gr "spritevisible pizza off"
       #gr "spritexy pizza -200 0"
       pizzaOff=1
       points=points+1
       if (points mod ptsPerCrab = 0) and (points/ptsPerCrab+1 <= maxCrabs) then
       'release The Kraken
           iCr = points/ptsPerCrab+1
           call releaseTheCrab iCr, crabW(iCr), crabH(iCr)
       end if
   end if

   if pizzaOff and (time$("ms")>t2Return) then
       #gr "spritevisible pizza on"
       px=int(rnd(0)*(2*cx-pizzaW))
       py=int(rnd(0)*(2*cy-pizzaH))
       #gr "spritexy pizza ";px;" ";py
       pizzaOff=0
   end if

   if isRun and hit=0 then
       if instr(list$, "crab") then
'use intersectW here
   'cave: x,y, manW, manH
   'crab ???
           isHit=0
           for i=1 to maxCrabs
               sprName$="crab";i
               #gr "spritexy? ";sprName$;" crX crY"
               if intersectW(x,manW,crX,crabW(i)) and _
                    intersectW(y,manH,crY,crabH(i)) then
                   isHit=1: exit for
               end if
           next
           if isHit then
               t2Return=time$("ms")+1000
               hit=1
               msg$="  Ouch!  "
                    '1234567890
               hp=hp-1
               if hp <1 then'die
                   isRun=0
                   msg$="Game over!"
                   #gr "spriteorient cave flip"
                   #gr "spritemovexy cave 0 -3"
                   #gr "cyclesprite cave 0"
               end if
           end if
       end if
   end if

   if isRun and hit and (time$("ms")>t2Return) then
       hit=0
       msg$=space$(10)
   end if

   for i = 1 to maxCrabs
       sprName$="crab";i
       #gr "spritexy? ";sprName$;" x y"
       crabVChanged=0
       if (x+crabW(i)>2*cx ) or (x<0) then crabVx(i)=0-crabVx(i): crabVChanged=1
       if (y+crabH(i)>2*cy ) or (y<0) then crabVy(i)=0-crabVy(i): crabVChanged=1
       if crabVChanged then
           #gr "spritemovexy ";sprName$;" ";crabVx(i);" ";crabVy(i)
           if crabVx(i) >0 then
               #gr "spriteorient ";sprName$;" mirror";
           else
               #gr "spriteorient ";sprName$;" normal";
           end if
       end if
   next

   #gr "DRAWSPRITES"
   'stats
   #gr "place 0 0"
   #gr "\\";using("###",points)

   #gr "place 250 0"
   #gr "\\";msg$


   #gr "place 550 0"
   #gr "\\";using("###",hp)
wait

[Move]
   toX = MouseX-manW/2    'mouse to center
   if toX>2*cx-manW then toX=2*cx-manW
   if toX<0 then toX=0
   toY = MouseY-manH/2
   if toY>2*cy-manH then toY=2*cy-manH
   if toY<0 then toY=0
wait

[quit]
   timer 0
   close #gr
end

'============================
sub releaseTheCrab i, crabW, crabH
   sprName$="crab";i
   #gr "spritexy? cave x y"
   while 1    'until new crab far enough
       px=int(rnd(0)*(2*cx-crabW))
       py=int(rnd(0)*(2*cy-crabH))
       if sqr((x-px)^2+(y-py)^2) > 150 then exit while
   wend
   #gr "spritexy ";sprName$;" ";px;" ";py
   #gr "spritemovexy ";sprName$;" ";crabVx(i);" ";crabVy(i)
end sub

sub loadSprites gr$, sprPath$, sprName$, sprBmps$, byref width, byref height
   width=0
   i=0
   while 1
       i=i+1
       bmp$=word$(sprBmps$,i)
       if bmp$="" then exit while
       fileName$=sprPath$+bmp$+".bmp"
       'print bmp$, fileName$
       loadbmp bmp$, fileName$
       if width=0 then
           call GetBmpDimensions fileName$, width, height
           height=height/2    'minus sprite mask
       end if
   wend
   #gr$ "addsprite ";sprName$;" ";sprBmps$
end sub

'from JBFreeForm
sub GetBmpDimensions fileName$, byref width, byref height
   open fileName$ for input as #gbd
   temp$ = input$(#gbd, 24)
   close #gbd
   width = asc(mid$(temp$, 19, 1))+asc(mid$(temp$, 20, 1))*256
   height = asc(mid$(temp$, 23, 1))+asc(mid$(temp$, 24, 1))*256
end sub

function intersect(a,b,c,d)
'does AB intersects CD?
   if a<c and c <b then intersect=1: exit function
   if a<d and d <b then intersect=1: exit function
   if c<a and b <d then intersect=1: exit function
end function

function intersectW(a,w1,c,w2)
'does AB intersects CD?
   b=a+w1: d=c+w2
   if a<c and c <b then intersectW=1: exit function
   if a<d and d <b then intersectW=1: exit function
   if c<a and b <d then intersectW=1: exit function
end function


[carlgundel]

That's cool. It's more fun (for me) if the timer ticks faster. Why can't you stun or kill the crabs somehow? Power-ups?

[carlgundel]

Jan 14, 2019 18:25:37 GMT carlgundel said:

That's cool. It's more fun (for me) if the timer ticks faster. Why can't you stun or kill the crabs somehow? Power-ups?

What if eating a pizza gave you strength to kill crabs temporarily, like Pac Man?

[tsh73]

I thought about visual feedback of power up
(or crab being hit / frozen)
I hardly could re-color sprite on the fly
but I could scale it up
and make move in different way (jumping)

Have to try some of it.

BTW I still wonder how to make crab hit character only once per contact.
Now it is immune for 1 second, then if sprites still touch, next hit is registered.

[Rod]

Once hit and registered change the sprite ie remove the man and put a differently named man in place for a certain number of frames.